[arch-commits] Commit in libretro-ppsspp/repos (2 files)

Evangelos Foutras foutrelis at archlinux.org
Sat Apr 25 15:36:08 UTC 2020


    Date: Saturday, April 25, 2020 @ 15:36:07
  Author: foutrelis
Revision: 620886

archrelease: copy trunk to community-staging-x86_64

Added:
  libretro-ppsspp/repos/community-staging-x86_64/
  libretro-ppsspp/repos/community-staging-x86_64/PKGBUILD
    (from rev 620885, libretro-ppsspp/trunk/PKGBUILD)

----------+
 PKGBUILD |   96 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 96 insertions(+)

Copied: libretro-ppsspp/repos/community-staging-x86_64/PKGBUILD (from rev 620885, libretro-ppsspp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-25 15:36:07 UTC (rev 620886)
@@ -0,0 +1,96 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Duck Hunt <vaporeon at tfwno.gf>
+
+pkgname=libretro-ppsspp
+pkgver=26831
+pkgrel=2
+pkgdesc='Sony PlayStation Portable core'
+arch=(x86_64)
+url=https://github.com/libretro/ppsspp
+license=(GPL2)
+groups=(libretro)
+depends=(
+  glew
+  libgl
+  libretro-core-info
+  zlib
+)
+makedepends=(
+  cmake
+  git
+  libglvnd
+  mesa
+  python
+)
+source=(
+  libretro-ppsspp::git+https://github.com/hrydgard/ppsspp.git#commit=6df422800506236e6703f3a114dd0ade976ac3c9
+  git+https://github.com/Kingcom/armips.git
+  git+https://github.com/discordapp/discord-rpc.git
+  git+https://github.com/hrydgard/ppsspp-ffmpeg.git
+  ppsspp-glslang::git+https://github.com/hrydgard/glslang.git
+  git+https://github.com/hrydgard/ppsspp-lang.git
+  git+https://github.com/Tencent/rapidjson.git
+  git+https://github.com/KhronosGroup/SPIRV-Cross.git
+  armips-tinyformat::git+https://github.com/Kingcom/tinyformat.git
+)
+sha256sums=(
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+)
+
+pkgver() {
+  cd libretro-ppsspp
+
+  git rev-list --count HEAD
+}
+
+prepare() {
+  cd libretro-ppsspp
+
+  for submodule in ffmpeg assets/lang ext/glslang; do
+    git submodule init ${submodule}
+    git config submodule.${submodule}.url ../ppsspp-${submodule#*/}
+    git submodule update ${submodule}
+  done
+  for submodule in ext/{armips,discord-rpc,rapidjson,SPIRV-Cross}; do
+    git submodule init ${submodule}
+    git config submodule.${submodule}.url ../${submodule#*/}
+    git submodule update ${submodule}
+  done
+
+  cd ext/armips
+
+  for submodule in ext/tinyformat; do
+    git submodule init ${submodule}
+    git config submodule.${submodule}.url ../../../armips-${submodule#*/}
+    git submodule update ${submodule}
+  done
+}
+
+build() {
+  cmake -S libretro-ppsspp -B build \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_SKIP_RPATH=ON \
+    -DOpenGL_GL_PREFERENCE=GLVND \
+    -DHEADLESS=OFF \
+    -DLIBRETRO=ON \
+    -DMOBILE_DEVICE=OFF \
+    -DSIMULATOR=OFF \
+    -DUNITTEST=OFF \
+    -DUSING_QT_UI=OFF
+  make -C build
+}
+
+package() {
+  install -Dm 644 build/lib/ppsspp_libretro.so -t "${pkgdir}"/usr/lib/libretro/
+  install -Dm 644 libretro-ppsspp/LICENSE.TXT -t "${pkgdir}"/usr/share/licenses/libretro-ppsspp-git/
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list