[arch-commits] Commit in haskell-doctemplates/repos (2 files)

[Felix Yan]

    Date: Saturday, April 25, 2020 @ 23:01:25
  Author: felixonmars
Revision: 621177

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-doctemplates/repos/community-staging-x86_64/
  haskell-doctemplates/repos/community-staging-x86_64/PKGBUILD
    (from rev 621176, haskell-doctemplates/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-doctemplates/repos/community-staging-x86_64/PKGBUILD (from rev 621176, haskell-doctemplates/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-25 23:01:25 UTC (rev 621177)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=doctemplates
+pkgname=haskell-doctemplates
+pkgver=0.8.2
+pkgrel=3
+pkgdesc="Pandoc-style document templates"
+url="https://github.com/jgm/doctemplates"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-doclayout' 'haskell-hsyaml' 'haskell-safe'
+         'haskell-scientific' 'haskell-text-conversions' 'haskell-unordered-containers'
+         'haskell-vector')
+makedepends=('ghc' 'haskell-glob' 'haskell-tasty' 'haskell-tasty-golden' 'haskell-tasty-hunit'
+             'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('1e1dbb8f8a2980b342ef3b5c2c0fefa8d0bf220d5ca1332de3dbdf30ab3243fd6f4d12816fa25851498a26c25c5fba1bc2aa6f16eafca11c65bc125a203b90ad')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}