[arch-commits] Commit in haskell-http-client/repos (2 files)

[Felix Yan]

    Date: Saturday, April 25, 2020 @ 23:56:42
  Author: felixonmars
Revision: 621221

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-client/repos/community-staging-x86_64/
  haskell-http-client/repos/community-staging-x86_64/PKGBUILD
    (from rev 621220, haskell-http-client/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-http-client/repos/community-staging-x86_64/PKGBUILD (from rev 621220, haskell-http-client/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-25 23:56:42 UTC (rev 621221)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-client
+pkgname=haskell-http-client
+pkgver=0.6.4.1
+pkgrel=43
+pkgdesc="An HTTP client engine"
+url="https://github.com/snoyberg/http-client"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-builder' 'haskell-case-insensitive' 'haskell-cookie'
+         'haskell-http-types' 'haskell-memory' 'haskell-mime-types'
+         'haskell-network' 'haskell-network-uri' 'haskell-random' 'haskell-streaming-commons'
+        )
+makedepends=('ghc' 'haskell-async' 'haskell-hspec' 'haskell-monad-control' 'haskell-zlib')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b9595ebf3cb48c5ed288934976b78270a3092a35ae083853684c848301ee88a18e0e41534180033df071ab87dc9f9cbab99da37cbc74d538472409c13dcfce7d')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid -fnetwork-uri
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}