[arch-commits] Commit in haskell-gi/repos (2 files)

[Felix Yan]

    Date: Sunday, April 26, 2020 @ 03:47:41
  Author: felixonmars
Revision: 621331

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-gi/repos/community-staging-x86_64/
  haskell-gi/repos/community-staging-x86_64/PKGBUILD
    (from rev 621330, haskell-gi/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-gi/repos/community-staging-x86_64/PKGBUILD (from rev 621330, haskell-gi/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-26 03:47:41 UTC (rev 621331)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=haskell-gi
+pkgname=haskell-gi
+pkgver=0.23.1
+pkgrel=6
+pkgdesc="Generate Haskell bindings for GObject Introspection capable libraries"
+url="https://github.com/haskell-gi/haskell-gi"
+license=("LGPL2")
+arch=('x86_64')
+depends=('ghc-libs' 'glib2' 'haskell-gi-base' 'haskell-ansi-terminal' 'haskell-attoparsec'
+         'haskell-pretty-show' 'haskell-safe' 'haskell-xdg-basedir' 'haskell-xml-conduit'
+         'haskell-regex-tdfa')
+makedepends=('ghc' 'gobject-introspection' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('646d19bfe4c36b86a5ea9e65f6b676f2a3cedc05d13f28574423b4295f12d2985423e516f4e679259d749029f3d606aa384b456efbf80775565d8d24f5a32f6b')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}