[arch-commits] Commit in tpm2-tss/repos (2 files)

[Evangelos Foutras]

    Date: Sunday, April 26, 2020 @ 04:58:05
  Author: foutrelis
Revision: 621380

archrelease: copy trunk to community-staging-x86_64

Added:
  tpm2-tss/repos/community-staging-x86_64/
  tpm2-tss/repos/community-staging-x86_64/PKGBUILD
    (from rev 621379, tpm2-tss/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: tpm2-tss/repos/community-staging-x86_64/PKGBUILD (from rev 621379, tpm2-tss/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-26 04:58:05 UTC (rev 621380)
@@ -0,0 +1,41 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+# Contributor: Bruno Pagani <archange at archlinux.org>
+pkgname=tpm2-tss
+pkgver=2.4.0
+pkgrel=2
+pkgdesc='Implementation of the TCG Trusted Platform Module 2.0 Software Stack (TSS2)'
+arch=('x86_64')
+url='https://github.com/tpm2-software/tpm2-tss'
+license=('BSD')
+depends=('curl' 'openssl' 'json-c')
+makedepends=('doxygen')
+checkdepends=('cmocka' 'ibm-sw-tpm2' 'iproute2' 'procps-ng' 'uthash')
+backup=('etc/tpm2-tss/fapi-config.json'
+        'etc/tpm2-tss/fapi-profiles/P_ECCP256SHA256.json'
+        'etc/tpm2-tss/fapi-profiles/P_RSA2048SHA256.json')
+source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"{,.asc})
+sha512sums=('763370381584f2124f751f0736e6a8b34428fd52134fd9966f3581e128f3b74b3f1261992f5d6162d7c866e47f7e5519ea80c1d1d39b80d5ed6e067eb2cd35a0'
+            'SKIP')
+validpgpkeys=('D760B790CCF0A41CBE7B047C316CC1FB24ABDC72'  # Tadeusz Struk <tadeusz.struk at intel.com>
+              'D6B4D8BAC7E0CC97DCD4AC7272E88B53F7A95D84'  # Andreas Fuchs <andreas.fuchs at sit.fraunhofer.de>
+              '5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1') # William Roberts (Bill Roberts) <william.c.roberts at intel.com>
+
+build() {
+	cd "$pkgname-$pkgver"
+	./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+	            --with-runstatedir=/run --with-sysusersdir=/usr/lib/sysusers.d \
+	            --with-tmpfilesdir=/usr/lib/tmpfiles.d --with-udevrulesprefix=60- \
+	            $( ((CHECKFUNC)) && echo --enable-unit --enable-integration)
+	make
+}
+
+check() {
+	cd "$pkgname-$pkgver"
+	make check
+}
+
+package() {
+	cd "$pkgname-$pkgver"
+	make DESTDIR="$pkgdir" install
+	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}