[arch-commits] Commit in nodejs-lts-dubnium/repos (2 files)

[Evangelos Foutras]

    Date: Monday, April 27, 2020 @ 07:54:27
  Author: foutrelis
Revision: 621795

archrelease: copy trunk to community-staging-x86_64

Added:
  nodejs-lts-dubnium/repos/community-staging-x86_64/
  nodejs-lts-dubnium/repos/community-staging-x86_64/PKGBUILD
    (from rev 621794, nodejs-lts-dubnium/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: nodejs-lts-dubnium/repos/community-staging-x86_64/PKGBUILD (from rev 621794, nodejs-lts-dubnium/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-27 07:54:27 UTC (rev 621795)
@@ -0,0 +1,68 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=nodejs-lts-dubnium
+pkgver=10.20.1
+pkgrel=2
+pkgdesc="Evented I/O for V8 javascript (LTS release: Dubnium)"
+arch=(x86_64)
+url="https://nodejs.org/"
+license=(MIT)
+depends=(openssl zlib icu libuv http-parser c-ares libnghttp2)
+makedepends=(python2 procps-ng)
+optdepends=('npm: nodejs package manager')
+provides=("nodejs=$pkgver")
+conflicts=(nodejs)
+source=("${url}/dist/v${pkgver}/node-v${pkgver}.tar.xz")
+# https://nodejs.org/download/release/latest-dubnium/SHASUMS256.txt.asc
+sha256sums=(ee1f88a04c608aeda1299bbcb0895eebb6394e901f03398c377236905d95f492)
+validpgpkeys=(C4F0DFFF4E8C1A8236409D08E73BC641CC11F4C8  # Myles Borins <mylesborins at google.com>
+              77984A986EBC2AA786BC0F66B01FBB92821C587A  # Gibson Fahnestock <gibfahn at gmail.com>
+              B9AE9905FFD7803F25714661B63B535A4C206CA9  # Evan Lucas <evanlucas at me.com> 
+              DD8F2338BAE7501E3DD5AC78C273792F7D83545D  # Rod Vagg <rod at vagg.org>
+              B9E2F5981AA6E0CD28160D9FF13993A75599653C  # Shelley Vohr <shelley.vohr at gmail.com>
+              4ED778F539E3634C779C87C6D7062848A1AB005C) # Beth Griggs <Bethany.Griggs at uk.ibm.com>
+
+prepare() {
+  cd node-v${pkgver}
+
+  echo 'Fixing for python2 name'
+  find -type f -exec sed \
+    -e 's_^#!/usr/bin/env python$_&2_' \
+    -e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
+    -e 's_^#!/usr/bin/python$_&2_' \
+    -e 's_^\( *exec \+\)python\( \+.*\)$_\1python2\2_'\
+    -e 's_^\(.*\)python\( \+-c \+.*\)$_\1python2\2_'\
+    -e "s_'python'_'python2'_" -i {} \;
+  find test/ -type f -exec sed 's_python _python2 _' -i {} \;
+}
+
+build() {
+  cd node-v${pkgver}
+
+  export PYTHON=python2
+  ./configure \
+    --prefix=/usr \
+    --with-intl=system-icu \
+    --without-npm \
+    --shared-openssl \
+    --shared-zlib \
+    --shared-libuv \
+    --shared-http-parser \
+    --shared-cares \
+    --shared-nghttp2
+
+  make
+}
+
+check() {
+  cd node-v${pkgver}
+  # https://github.com/nodejs/node/issues/32765
+  sed -i '/\$(MAKE) -s test-doc/d' Makefile
+  make test
+}
+
+package() {
+  cd node-v${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}