[arch-commits] Commit in evolution-data-server/repos (2 files)

Evangelos Foutras foutrelis at archlinux.org
Mon Apr 27 12:27:59 UTC 2020


    Date: Monday, April 27, 2020 @ 12:27:58
  Author: foutrelis
Revision: 381716

archrelease: copy trunk to staging-x86_64

Added:
  evolution-data-server/repos/staging-x86_64/
  evolution-data-server/repos/staging-x86_64/PKGBUILD
    (from rev 381715, evolution-data-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: evolution-data-server/repos/staging-x86_64/PKGBUILD (from rev 381715, evolution-data-server/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-04-27 12:27:58 UTC (rev 381716)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=evolution-data-server
+pkgver=3.36.2
+pkgrel=2
+pkgdesc="Centralized access to appointments and contacts"
+url="https://wiki.gnome.org/Apps/Evolution"
+arch=(x86_64)
+depends=(gnome-online-accounts nss krb5 libgweather libical db libgdata libphonenumber)
+makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git cmake)
+provides=(libcamel-1.2.so libebackend-1.2.so libebook-1.2.so libebook-contacts-1.2.so
+          libecal-2.0.so libedata-book-1.2.so libedata-cal-2.0.so libedataserver-1.2.so
+          libedataserverui-1.2.so)
+license=(GPL)
+_commit=f99698754bf281b920a6efeeba00bc9174762fb6  # tags/3.36.2^0
+source=("git+https://gitlab.gnome.org/GNOME/evolution-data-server.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  cmake -H$pkgname -Bbuild \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIBEXEC_INSTALL_DIR=/usr/lib \
+    -DSYSCONF_INSTALL_DIR=/etc \
+    -DENABLE_INTROSPECTION=ON \
+    -DENABLE_VALA_BINDINGS=ON \
+    -DENABLE_GTK_DOC=ON \
+    -DWITH_PHONENUMBER=ON
+  cmake --build build
+}
+
+check() {
+  # libedata-book tests fail because they try to
+  # mkdir /usr/lib/evolution-data-server/camel-providers
+  cmake --build build --target test || :
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --build build --target install
+}


More information about the arch-commits mailing list