[arch-commits] Commit in ledger/repos (2 files)

[Evangelos Foutras]

    Date: Monday, April 27, 2020 @ 19:24:15
  Author: foutrelis
Revision: 621923

archrelease: copy trunk to community-staging-x86_64

Added:
  ledger/repos/community-staging-x86_64/
  ledger/repos/community-staging-x86_64/PKGBUILD
    (from rev 621922, ledger/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: ledger/repos/community-staging-x86_64/PKGBUILD (from rev 621922, ledger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-27 19:24:15 UTC (rev 621923)
@@ -0,0 +1,42 @@
+# Maintainer: Ivy Foster <code at iff.ink>
+# Contributor: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: Abdelhakim Qbaich <abdelhakim at qbaich.com>
+# Contributor: korjjj <korjjj+aur at gmail.com>
+# Contributor: TDY <tdy at archlinux.info>
+# Contributor: Adam Ehlers Nyholm Thomsen <adament at gmail.com>
+# Contributor: Nathan Jones <nathanj at insightbb.com>
+
+pkgname=ledger
+pkgver=3.1.3
+pkgrel=6
+pkgdesc='Double-entry accounting system with a command-line reporting interface'
+arch=(i686 x86_64)
+url='https://ledger-cli.org'
+license=(BSD)
+depends=(boost-libs libedit mpfr)
+makedepends=(boost cmake)
+optdepends=('emacs: emacs interface')
+source=("ledger-$pkgver.tar.gz::https://github.com/ledger/ledger/archive/v$pkgver.tar.gz")
+sha256sums=(b248c91d65c7a101b9d6226025f2b4bf3dabe94c0c49ab6d51ce84a22a39622b)
+
+build() {
+	cd "ledger-$pkgver"
+
+	cmake . \
+		-DCMAKE_INSTALL_PREFIX:PATH=/usr \
+		-DCMAKE_INSTALL_LIBDIR:PATH=lib \
+		-DUSE_PYTHON:BOOL=FALSE \
+		-DBUILD_EMACSLISP:BOOL=TRUE
+	make
+}
+
+check() {
+	make -C "ledger-$pkgver" check
+}
+
+package() {
+	cd "ledger-$pkgver"
+
+	make DESTDIR="$pkgdir" install
+	install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/ledger/LICENSE.md"
+}