[arch-commits] Commit in mapnik/repos (2 files)

[Evangelos Foutras]

    Date: Monday, April 27, 2020 @ 20:10:27
  Author: foutrelis
Revision: 621935

archrelease: copy trunk to community-staging-x86_64

Added:
  mapnik/repos/community-staging-x86_64/
  mapnik/repos/community-staging-x86_64/PKGBUILD
    (from rev 621934, mapnik/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: mapnik/repos/community-staging-x86_64/PKGBUILD (from rev 621934, mapnik/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-27 20:10:27 UTC (rev 621935)
@@ -0,0 +1,45 @@
+# Maintainer: Jaroslav Lichtblau <svetlemodry at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: David Dent <thewinch at gmail.com>
+# Contributor: orbisvicis <orbisvicis at gmail.com>
+
+pkgname=mapnik
+pkgver=3.0.23
+pkgrel=2
+pkgdesc="Free Toolkit for developing mapping applications and rendering beautiful maps"
+arch=('x86_64')
+url="https://mapnik.org/"
+license=('LGPL')
+depends=('boost-libs' 'cairo' 'freetype2' 'gdal' 'harfbuzz' 'icu' 'libjpeg-turbo' 'libpng'
+         'libtiff' 'libwebp' 'libxml2' 'postgresql-libs' 'proj' 'sqlite' 'zlib')
+makedepends=('boost' 'scons')
+source=(https://github.com/$pkgname/$pkgname/releases/download/v$pkgver/$pkgname-v$pkgver.tar.bz2
+        mapnik-freetype2.patch::https://github.com/mapnik/mapnik/pull/3892.patch)
+sha256sums=('4b1352e01f7ce25ab099e586d7ae98e0b74145a3bf94dd365cb0a2bdab3b9dc2'
+            '774a8590b698e9dc2a483e6ff48781ed0400ba06b901f12a1ed50c9114833d47')
+
+prepare() {
+  cd "${srcdir}"/$pkgname-v$pkgver
+
+  # Use pkg-config to find FreeType2 if available
+  # https://github.com/mapnik/mapnik/pull/3892
+  patch -Np1 -i "${srcdir}"/mapnik-freetype2.patch
+}
+
+build() {
+  cd "${srcdir}"/$pkgname-v$pkgver
+  scons configure  FAST=True \
+    PREFIX="/usr" \
+    INPUT_PLUGINS=all \
+    XMLPARSER=libxml2 \
+    DESTDIR="$pkgdir" \
+    CUSTOM_CXXFLAGS="$CXXFLAGS" \
+    CUSTOM_LDFLAGS="$LDFLAGS" \
+    CUSTOM_DEFINES="-DACCEPT_USE_OF_DEPRECATED_PROJ_API_H=1"
+  scons $(expr "$MAKEFLAGS" : '.*\(\-j[0-9]\+\)')
+}
+
+package(){
+  cd "${srcdir}"/$pkgname-v$pkgver
+  scons install
+}