[arch-commits] Commit in haskell-pandoc-types/repos (2 files)

[Felix Yan]

    Date: Thursday, April 30, 2020 @ 19:55:44
  Author: felixonmars
Revision: 623386

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-pandoc-types/repos/community-staging-x86_64/
  haskell-pandoc-types/repos/community-staging-x86_64/PKGBUILD
    (from rev 623385, haskell-pandoc-types/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-pandoc-types/repos/community-staging-x86_64/PKGBUILD (from rev 623385, haskell-pandoc-types/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-04-30 19:55:44 UTC (rev 623386)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=pandoc-types
+pkgname=haskell-pandoc-types
+pkgver=1.20
+pkgrel=33
+pkgdesc="Types for representing a structured document"
+url="https://pandoc.org/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-quickcheck' 'haskell-syb')
+makedepends=('ghc' 'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-quickcheck2' 'haskell-hunit' 'haskell-string-qq')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('36c658093237246a344dc65bf9e214b250ea1a0aecf9931d80299f44ee152553c4326948bfae8e0f3e5aaabe93bc7a9aca0c79383e48b0f9d2696383df2b40ee')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *2.14/<3/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}