[arch-commits] Commit in (libtpms libtpms/repos libtpms/trunk libtpms/trunk/PKGBUILD)

[Jonas Witschel]

    Date: Wednesday, August 5, 2020 @ 07:04:50
  Author: diabonas
Revision: 669042

Add package libtpms (dependency of swtpm)

Added:
  libtpms/
  libtpms/repos/
  libtpms/trunk/
  libtpms/trunk/PKGBUILD

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Added: libtpms/trunk/PKGBUILD
===================================================================
--- libtpms/trunk/PKGBUILD	                        (rev 0)
+++ libtpms/trunk/PKGBUILD	2020-08-05 07:04:50 UTC (rev 669042)
@@ -0,0 +1,41 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=libtpms
+pkgver=0.7.3
+_tag=ed3b1a758c839bce3c210e2b734f4ea34b74951e # git rev-parse "v$pkgver"
+pkgrel=2
+pkgdesc='Library providing a software emulation of a Trusted Platform Module (TPM 1.2 and TPM 2.0)'
+arch=('x86_64')
+url='https://github.com/stefanberger/libtpms'
+license=('BSD')
+depends=('openssl')
+makedepends=('git')
+source=("git+$url.git?signed#tag=$_tag")
+sha512sums=('SKIP')
+validpgpkeys=('B818B9CADF9089C2D5CEC66B75AD65802A0B4211') # Stefan Berger <stefanb at linux.vnet.ibm.com>
+
+pkgver() {
+	cd "$pkgname"
+	git describe | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+	cd "$pkgname"
+	autoreconf --install --force
+}
+
+build() {
+	cd "$pkgname"
+	./configure --prefix=/usr --with-openssl --with-tpm2
+	make
+}
+
+check() {
+	cd "$pkgname"
+	make check
+}
+
+package() {
+	cd "$pkgname"
+	make DESTDIR="$pkgdir" install
+	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}