[arch-commits] Commit in tpm2-tss/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Jonas Witschel diabonas at archlinux.org
Wed Aug 5 07:25:22 UTC 2020


    Date: Wednesday, August 5, 2020 @ 07:25:22
  Author: diabonas
Revision: 669051

archrelease: copy trunk to staging-x86_64

Added:
  tpm2-tss/repos/staging-x86_64/
  tpm2-tss/repos/staging-x86_64/PKGBUILD
    (from rev 669050, tpm2-tss/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: tpm2-tss/repos/staging-x86_64/PKGBUILD (from rev 669050, tpm2-tss/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-08-05 07:25:22 UTC (rev 669051)
@@ -0,0 +1,42 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+# Contributor: Bruno Pagani <archange at archlinux.org>
+pkgname=tpm2-tss
+pkgver=3.0.0
+pkgrel=1
+pkgdesc='Implementation of the TCG Trusted Platform Module 2.0 Software Stack (TSS2)'
+arch=('x86_64')
+url='https://github.com/tpm2-software/tpm2-tss'
+license=('BSD')
+depends=('curl' 'json-c' 'openssl' 'libjson-c.so')
+makedepends=('doxygen')
+checkdepends=('cmocka' 'iproute2' 'swtpm' 'uthash')
+provides=('libtss2-esys.so' 'libtss2-fapi.so' 'libtss2-mu.so' 'libtss2-rc.so' 'libtss2-sys.so' 'libtss2-tctildr.so')
+backup=('etc/tpm2-tss/fapi-config.json'
+        'etc/tpm2-tss/fapi-profiles/P_ECCP256SHA256.json'
+        'etc/tpm2-tss/fapi-profiles/P_RSA2048SHA256.json')
+source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"{,.asc})
+sha512sums=('ba54904f2cd8cbcca85ce4d4ac5c8650da6ab076e8d8d142e1b7ee75c5e9a645520f1a5ac8ffe5269deceba84762c9074b131296e8b2d4c684ddc335a828d7a8'
+            'SKIP')
+validpgpkeys=('D760B790CCF0A41CBE7B047C316CC1FB24ABDC72'  # Tadeusz Struk <tadeusz.struk at intel.com>
+              'D6B4D8BAC7E0CC97DCD4AC7272E88B53F7A95D84'  # Andreas Fuchs <andreas.fuchs at sit.fraunhofer.de>
+              '5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1') # William Roberts (Bill Roberts) <william.c.roberts at intel.com>
+
+build() {
+	cd "$pkgname-$pkgver"
+	./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+	            --with-runstatedir=/run --with-sysusersdir=/usr/lib/sysusers.d \
+	            --with-tmpfilesdir=/usr/lib/tmpfiles.d --with-udevrulesprefix=60- \
+	            $( ((CHECKFUNC)) && echo --enable-unit --enable-integration)
+	make
+}
+
+check() {
+	cd "$pkgname-$pkgver"
+	make check
+}
+
+package() {
+	cd "$pkgname-$pkgver"
+	make DESTDIR="$pkgdir" install
+	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}


More information about the arch-commits mailing list