[arch-commits] Commit in tpm2-tools/repos (2 files)

Jonas Witschel diabonas at archlinux.org
Wed Aug 5 07:36:55 UTC 2020


    Date: Wednesday, August 5, 2020 @ 07:36:55
  Author: diabonas
Revision: 669057

archrelease: copy trunk to community-staging-x86_64

Added:
  tpm2-tools/repos/community-staging-x86_64/
  tpm2-tools/repos/community-staging-x86_64/PKGBUILD
    (from rev 669056, tpm2-tools/trunk/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: tpm2-tools/repos/community-staging-x86_64/PKGBUILD (from rev 669056, tpm2-tools/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-05 07:36:55 UTC (rev 669057)
@@ -0,0 +1,35 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+# Contributor: Bruno Pagani <archange at archlinux.org>
+pkgname=tpm2-tools
+pkgver=4.2.1
+pkgrel=2
+pkgdesc='Trusted Platform Module 2.0 tools based on tpm2-tss'
+arch=('x86_64')
+url='https://github.com/tpm2-software/tpm2-tools'
+license=('BSD')
+depends=('curl' 'libutil-linux' 'openssl' 'tpm2-tss' 'libtss2-esys.so' 'libtss2-fapi.so'
+         'libtss2-mu.so' 'libtss2-rc.so' 'libtss2-sys.so' 'libtss2-tctildr.so')
+checkdepends=('cmocka' 'expect' 'ibm-sw-tpm2' 'iproute2' 'python-yaml' 'tpm2-abrmd' 'xxd')
+optdepends=('tpm2-abrmd: user space resource manager')
+source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"{,.asc})
+sha512sums=('4da103e70880d72a9aa402dea39ea439a0657729af22f08ac7275022c475ab46cb3dd6123d6846669d9b7f8f9af7b3e3df7c3b1d33cd0149b649b7941c84c339'
+            'SKIP')
+validpgpkeys=('5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1'  # William Roberts (Bill Roberts) <william.c.roberts at intel.com>
+              '6313E6DC41AAFC315A8760A414986F6944B1F72B') # Desai, Imran (idesai-github-gpg) <imran.desai at intel.com>
+
+build() {
+	cd "$pkgname-$pkgver"
+	./configure --prefix=/usr $( ((CHECKFUNC)) && echo --enable-unit)
+	make
+}
+
+check() {
+	cd "$pkgname-$pkgver"
+	make check
+}
+
+package() {
+	cd "$pkgname-$pkgver"
+	make DESTDIR="$pkgdir" install
+	install -Dm644 doc/LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}


More information about the arch-commits mailing list