[arch-commits] Commit in marble/repos (3 files)

[Antonio Rojas]

    Date: Wednesday, August 5, 2020 @ 12:22:45
  Author: arojas
Revision: 393178

archrelease: copy trunk to staging-x86_64

Added:
  marble/repos/staging-x86_64/
  marble/repos/staging-x86_64/PKGBUILD
    (from rev 393177, marble/trunk/PKGBUILD)
  marble/repos/staging-x86_64/marble-gpsd-3.21.patch
    (from rev 393177, marble/trunk/marble-gpsd-3.21.patch)

------------------------+
 PKGBUILD               |   76 +++++++++++++++++++++++++++++++++++++++++++++++
 marble-gpsd-3.21.patch |   16 +++++++++
 2 files changed, 92 insertions(+)

Copied: marble/repos/staging-x86_64/PKGBUILD (from rev 393177, marble/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-08-05 12:22:45 UTC (rev 393178)
@@ -0,0 +1,76 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+# Contributor: Balló György <ballogyor+arch at gmail dot com>
+
+pkgbase=marble
+pkgname=(marble-common marble-qt marble)
+pkgver=20.04.3
+pkgrel=2
+pkgdesc="Desktop Globe"
+arch=(x86_64)
+url="https://www.kde.org/applications/system/marble"
+license=(GPL)
+makedepends=(extra-cmake-modules gpsd kdoctools knewstuff kparts krunner libwlocate phonon-qt5
+             plasma-workspace qt5-serialport qt5-tools qt5-webengine shapelib)
+source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgbase-$pkgver.tar.xz"{,.sig}
+         marble-gpsd-3.21.patch)
+sha256sums=('9c0b6fb13d53e1748de081c43e06cc132d5b07d46e594443b207fbaf74e1f95b'
+            'SKIP'
+            'cfb30ebcefd5134c7b11525160537d1deee7cbd707df4fd8d59da4d9bd5bbd9c')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  patch -d $pkgbase-$pkgver -p1 -i ../marble-gpsd-3.21.patch # Fix build with gpsd 3.21
+}
+
+build() {
+  cmake -B build -S $pkgbase-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_SYSCONFDIR=/etc \
+    -DQT_PLUGINS_DIR=lib/qt/plugins \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_MARBLE_EXAMPLES=OFF \
+    -DBUILD_MARBLE_TESTS=OFF \
+    -DMOBILE=OFF
+  cmake --build build
+}
+
+package_marble-common() {
+  pkgdesc='Common libraries and plugins for Marble'
+  depends=(qt5-svg qt5-webengine phonon-qt5 desktop-file-utils)
+  optdepends=('gpsd: GPS based geolocation'
+              'libwlocate: WLAN based geolocation'
+              'qt5-serialport: APRS plugin'
+              'shapelib: SHP plugin')
+
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/usr/share/{config.kcfg,kxmlgui5,metainfo,plasma} \
+        "$pkgdir"/usr/bin \
+        "$pkgdir"/etc \
+        "$pkgdir"/usr/lib/qt/{qml,plugins/*.so} \
+        "$pkgdir"/usr/share/applications/{marble_geo.desktop,marble_worldwind.desktop,org.kde.marble*.desktop} \
+        "$pkgdir"/usr/share/kservices5/{marble_part.desktop,plasma*} \
+        "$pkgdir"/usr/share/locale/*/LC_MESSAGES/*.mo
+}
+
+package_marble-qt() {
+  pkgdesc+=' (Qt version)'
+  depends=(marble-common)
+
+  DESTDIR="$pkgdir" cmake --install build/src/apps/marble-qt
+}
+
+package_marble() {
+  depends=(marble-common knewstuff kparts)
+  optdepends=('krunner: Krunner plugin')
+  groups=(kde-applications kde-education)
+
+  DESTDIR="$pkgdir" cmake --install build/src/apps/marble-kde
+  DESTDIR="$pkgdir" cmake --install build/src/plasma
+  DESTDIR="$pkgdir" cmake --install build/src/plasmarunner
+  DESTDIR="$pkgdir" cmake --install build/src/thumbnailer
+  rm -r "$pkgdir"/usr/share/{icons,doc/HTML}
+}

Copied: marble/repos/staging-x86_64/marble-gpsd-3.21.patch (from rev 393177, marble/trunk/marble-gpsd-3.21.patch)
===================================================================
--- staging-x86_64/marble-gpsd-3.21.patch	                        (rev 0)
+++ staging-x86_64/marble-gpsd-3.21.patch	2020-08-05 12:22:45 UTC (rev 393178)
@@ -0,0 +1,16 @@
+diff --git a/src/plugins/positionprovider/gpsd/GpsdPositionProviderPlugin.cpp b/src/plugins/positionprovider/gpsd/GpsdPositionProviderPlugin.cpp
+index 3a787eb1f..02dc4a355 100644
+--- a/src/plugins/positionprovider/gpsd/GpsdPositionProviderPlugin.cpp
++++ b/src/plugins/positionprovider/gpsd/GpsdPositionProviderPlugin.cpp
+@@ -79,7 +79,11 @@ void GpsdPositionProviderPlugin::update( gps_data_t data )
+ {
+     PositionProviderStatus oldStatus = m_status;
+     GeoDataCoordinates oldPosition = m_position;
++#if defined( GPSD_API_MAJOR_VERSION ) && ( GPSD_API_MAJOR_VERSION >= 10 )
++    if ( data.fix.status == STATUS_NO_FIX || std::isnan( data.fix.longitude ) || std::isnan( data.fix.latitude ) )
++#else
+     if ( data.status == STATUS_NO_FIX || std::isnan( data.fix.longitude ) || std::isnan( data.fix.latitude ) )
++#endif
+         m_status = PositionProviderStatusAcquiring;
+     else {
+         m_status = PositionProviderStatusAvailable;