[arch-commits] Commit in darcs/repos (2 files)

[Felix Yan]

    Date: Friday, August 7, 2020 @ 06:43:25
  Author: felixonmars
Revision: 671295

archrelease: copy trunk to community-staging-x86_64

Added:
  darcs/repos/community-staging-x86_64/
  darcs/repos/community-staging-x86_64/PKGBUILD
    (from rev 671294, darcs/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: darcs/repos/community-staging-x86_64/PKGBUILD (from rev 671294, darcs/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-07 06:43:25 UTC (rev 671295)
@@ -0,0 +1,63 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=darcs
+pkgver=2.14.4
+pkgrel=46
+pkgdesc="A distributed, interactive, smart revision control system"
+url="http://darcs.net"
+license=("GPL")
+arch=('x86_64')
+depends=('curl' 'ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-base16-bytestring'
+         'haskell-cryptohash' 'haskell-data-ordlist' 'haskell-fgl' 'haskell-graphviz'
+         'haskell-hashable' 'haskell-html' 'haskell-http' 'haskell-knob' 'haskell-mmap'
+         'haskell-network' 'haskell-network-uri' 'haskell-old-time'
+         'haskell-sandi' 'haskell-random' 'haskell-regex-applicative' 'haskell-regex-compat-tdfa'
+         'haskell-tar' 'haskell-unix-compat' 'haskell-utf8-string'
+         'haskell-vector' 'haskell-zip-archive' 'haskell-zlib')
+makedepends=('ghc' 'haskell-cmdargs' 'haskell-findbin' 'haskell-hunit' 'haskell-quickcheck'
+             'haskell-shelly' 'haskell-split' 'haskell-test-framework'
+             'haskell-test-framework-hunit' 'haskell-test-framework-quickcheck2')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('cea95edc542328402f258f66de52c8b9fda417ecd905f957f94e1a398809652dc2f6e873e230683af97601349e0ee03095c67ba45d9c044706e12275c3fc0300')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -e 's/^ghc /ghc -dynamic /' \
+        -e 's/ ghc / ghc -dynamic /' \
+        -i tests/*.sh tests/lib
+    sed -i -e 's/< *2.14/<3/' $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+        -fcurl -fpkgconfig -f-static -fterminfo -fthreaded -fexecutable \
+        -f-rts -foptimize -f-warn-as-error -f-libiconv
+    LD_LIBRARY_PATH="$srcdir"/$pkgname-$pkgver/dist/build runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+    chmod 644 "${pkgdir}/usr/share/man/man1/darcs.1"
+
+    install -Dm644 contrib/darcs_completion "${pkgdir}/usr/share/bash-completion/completions/darcs"
+    install -Dm644 contrib/_darcs.zsh "${pkgdir}/usr/share/zsh/site-functions/_darcs"
+}