[arch-commits] Commit in pcsx2/repos (2 files)

[Maxime Gauduin]

    Date: Friday, August 7, 2020 @ 13:13:19
  Author: alucryd
Revision: 671527

archrelease: copy trunk to multilib-testing-x86_64

Added:
  pcsx2/repos/multilib-testing-x86_64/
  pcsx2/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 671526, pcsx2/trunk/PKGBUILD)

----------+
 PKGBUILD |   79 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)

Copied: pcsx2/repos/multilib-testing-x86_64/PKGBUILD (from rev 671526, pcsx2/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2020-08-07 13:13:19 UTC (rev 671527)
@@ -0,0 +1,79 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: josephgbr <rafael.f.f1 at gmail.com>
+# Contributor: vEX <vex at niechift.com>
+
+pkgname=pcsx2
+pkgver=1.6.0
+pkgrel=2
+pkgdesc='A Sony PlayStation 2 emulator'
+arch=(x86_64)
+url=https://www.pcsx2.net
+license=(
+  GPL2
+  GPL3
+  LGPL2.1
+  LGPL3
+)
+depends=(
+  lib32-glew
+  lib32-libaio
+  lib32-libcanberra
+  lib32-libjpeg-turbo
+  lib32-libpcap
+  lib32-libpulse
+  lib32-libxml2
+  lib32-nvidia-cg-toolkit
+  lib32-ocl-icd
+  lib32-portaudio
+  lib32-sdl2
+  lib32-soundtouch
+  lib32-wxgtk3
+)
+makedepends=(
+  cmake
+  git
+  opencl-headers
+  png++
+)
+_tag=aaaf29557fe63870ede815dd6d2e48a98279ca59
+source=(git+https://github.com/PCSX2/pcsx2.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd pcsx2
+
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cmake -S pcsx2 -B build \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_TOOLCHAIN_FILE=cmake/linux-compiler-i386-multilib.cmake \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_LIBRARY_PATH=/usr/lib32 \
+    -DGAMEINDEX_DIR=/usr/share/pcsx2 \
+    -DPLUGIN_DIR=/usr/lib32/pcsx2 \
+    -DDISABLE_ADVANCE_SIMD=ON \
+    -DDISABLE_BUILD_DATE=ON \
+    -DDISABLE_PCSX2_WRAPPER=ON \
+    -DEXTRA_PLUGINS=ON \
+    -DEGL_API=OFF \
+    -DGLSL_API=ON \
+    -DGTK3_API=ON \
+    -DOPENCL_API=ON \
+    -DSDL2_API=ON \
+    -DPACKAGE_MODE=ON \
+    -DREBUILD_SHADER=ON \
+    -DUSE_LTO=OFF \
+    -DUSE_VTUNE=OFF \
+    -DXDG_STD=ON \
+    -DwxWidgets_CONFIG_EXECUTABLE=/usr/bin/wx-config32 \
+    -Wno-dev
+  make -C build
+}
+
+package() {
+  make DESTDIR="${pkgdir}" -C build install
+}
+
+# vim: ts=2 sw=2 et: