[arch-commits] Commit in haskell-binary-instances/repos (2 files)

[Felix Yan]

    Date: Wednesday, August 12, 2020 @ 19:26:07
  Author: felixonmars
Revision: 676585

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-binary-instances/repos/community-staging-x86_64/
  haskell-binary-instances/repos/community-staging-x86_64/PKGBUILD
    (from rev 676584, haskell-binary-instances/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-binary-instances/repos/community-staging-x86_64/PKGBUILD (from rev 676584, haskell-binary-instances/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-12 19:26:07 UTC (rev 676585)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=binary-instances
+pkgname=haskell-binary-instances
+pkgver=1.0.0.1
+pkgrel=30
+pkgdesc="Orphan instances for binary"
+url="https://github.com/phadej/binary-instances"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-binary-orphans' 'haskell-case-insensitive'
+         'haskell-hashable' 'haskell-scientific' 'haskell-tagged' 'haskell-text-binary'
+         'haskell-time-compat' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-vector-binary-instances')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-tasty'
+             'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('8933f2eab4a23460bd9be7547f229416adccb3e82ec452f75567fa5b5cb6babe4b7f243fbf3799099647bc4f890eaa1acc962128caa8caafc3ff724867585e3d')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *2.14/<3/;s/< *1.3/<2/;s/< *1.5/<2/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # https://github.com/phadej/binary-instances/issues/7
+    runhaskell Setup test || :
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}