[arch-commits] Commit in haskell-shakespeare/repos (2 files)

[Felix Yan]

    Date: Wednesday, August 12, 2020 @ 20:31:27
  Author: felixonmars
Revision: 676725

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-shakespeare/repos/community-staging-x86_64/
  haskell-shakespeare/repos/community-staging-x86_64/PKGBUILD
    (from rev 676724, haskell-shakespeare/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-shakespeare/repos/community-staging-x86_64/PKGBUILD (from rev 676724, haskell-shakespeare/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-12 20:31:27 UTC (rev 676725)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=shakespeare
+pkgname=haskell-shakespeare
+pkgver=2.0.24.1
+pkgrel=13
+pkgdesc="A toolkit for making compile-time interpolated templates"
+url="https://www.yesodweb.com/book/shakespearean-templates"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-blaze-html' 'haskell-blaze-markup'
+         'haskell-scientific' 'haskell-th-lift' 'haskell-unordered-containers'
+         'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ef95f79d34d5e6d707862973ec23fac6a3c11f042508606482f4936efcd7e8b95ae8b77a7147fe724c07233ab1c1886de8029374f7c6df3640c743c5bbd9deec')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-test_roy -f-test_coffee -f-test_export
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}