[arch-commits] Commit in haskell-store/repos (2 files)

[Felix Yan]

    Date: Thursday, August 13, 2020 @ 21:22:10
  Author: felixonmars
Revision: 678120

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-store/repos/community-staging-x86_64/
  haskell-store/repos/community-staging-x86_64/PKGBUILD
    (from rev 678119, haskell-store/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-store/repos/community-staging-x86_64/PKGBUILD (from rev 678119, haskell-store/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-13 21:22:10 UTC (rev 678120)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=store
+pkgname=haskell-store
+pkgver=0.7.6
+pkgrel=2
+pkgdesc="Fast binary serialization"
+url="https://github.com/fpco/store"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-base-orphans' 'haskell-base64-bytestring'
+         'haskell-contravariant' 'haskell-cryptohash' 'haskell-free'
+         'haskell-hashable' 'haskell-hspec' 'haskell-hspec-smallcheck' 'haskell-lifted-base'
+         'haskell-monad-control' 'haskell-mono-traversable' 'haskell-network' 'haskell-primitive'
+         'haskell-resourcet' 'haskell-safe' 'haskell-smallcheck'
+         'haskell-store-core' 'haskell-syb' 'haskell-th-lift' 'haskell-th-lift-instances'
+         'haskell-th-orphans' 'haskell-th-reify-many' 'haskell-th-utilities'
+         'haskell-unordered-containers' 'haskell-vector' 'haskell-void')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('c1bf63b76e300aabce656e06899de9b95fa5a3d9b08be47b6ed640f5ae2a63d5dbb08e8058bb334af6a771a2dc8eeb700bf7162b806481e47e08d22bbb83b674')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-comparison-bench -f-small-bench
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}