[arch-commits] Commit in haskell-yesod-static/repos (2 files)

[Felix Yan]

    Date: Saturday, August 15, 2020 @ 07:06:48
  Author: felixonmars
Revision: 679464

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-static/repos/community-staging-x86_64/
  haskell-yesod-static/repos/community-staging-x86_64/PKGBUILD
    (from rev 679463, haskell-yesod-static/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-yesod-static/repos/community-staging-x86_64/PKGBUILD (from rev 679463, haskell-yesod-static/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-15 07:06:48 UTC (rev 679464)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod-static
+pkgname=haskell-yesod-static
+pkgver=1.6.1.0
+pkgrel=25
+pkgdesc="Static file serving subsite for Yesod Web Framework."
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-base64-bytestring'
+         'haskell-blaze-builder' 'haskell-conduit' 'haskell-cryptonite'
+         'haskell-cryptonite-conduit' 'haskell-css-text' 'haskell-data-default'
+         'haskell-file-embed' 'haskell-hashable' 'haskell-hjsmin' 'haskell-http-types'
+         'haskell-memory' 'haskell-mime-types' 'haskell-rio' 'haskell-unix-compat'
+         'haskell-unordered-containers' 'haskell-wai' 'haskell-wai-app-static' 'haskell-yesod-core')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit' 'haskell-wai-extra' 'haskell-yesod-test')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('66037ec28eac83e374161c1b306a4d20805ecb35ccfc4878e7894d961daaf30d9936c6e209641ff323d7e3dd5626f5a24a12915d4205417c496e272a2e969f6e')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}