[arch-commits] Commit in haskell-generic-data/repos (2 files)

[Felix Yan]

    Date: Sunday, August 16, 2020 @ 14:42:10
  Author: felixonmars
Revision: 681562

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-generic-data/repos/community-staging-x86_64/
  haskell-generic-data/repos/community-staging-x86_64/PKGBUILD
    (from rev 681561, haskell-generic-data/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-generic-data/repos/community-staging-x86_64/PKGBUILD (from rev 681561, haskell-generic-data/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-16 14:42:10 UTC (rev 681562)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=generic-data
+pkgname=haskell-generic-data
+pkgver=0.9.0.0
+pkgrel=1
+pkgdesc="Deriving instances with GHC.Generics and related utilities"
+url="https://github.com/Lysxia/generic-data"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ap-normalize' 'haskell-base-orphans' 'haskell-contravariant'
+         'haskell-show-combinators')
+makedepends=('ghc' 'haskell-cabal-doctest' 'haskell-doctest' 'haskell-generic-lens' 'haskell-glob'
+             'haskell-inspection-testing' 'haskell-one-liner' 'haskell-quickcheck'
+             'haskell-show-combinators' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-unordered-containers')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('c5054d6909532a004d3ac0a91ec9e16ac917ae6c97d4ae5be0be0fa75de5bcf088bef8fe517a287dd352b024144c50a4ea7aef26a58ff0e0b5cc072cf8184884')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}