[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, August 17, 2020 @ 04:34:50
  Author: felixonmars
Revision: 682097

addpkg: haskell-commonmark-pandoc 0.2.0.0-1

Added:
  haskell-commonmark-pandoc/
  haskell-commonmark-pandoc/repos/
  haskell-commonmark-pandoc/trunk/
  haskell-commonmark-pandoc/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: haskell-commonmark-pandoc/trunk/PKGBUILD
===================================================================
--- haskell-commonmark-pandoc/trunk/PKGBUILD	                        (rev 0)
+++ haskell-commonmark-pandoc/trunk/PKGBUILD	2020-08-17 04:34:50 UTC (rev 682097)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=commonmark-pandoc
+pkgname=haskell-commonmark-pandoc
+pkgver=0.2.0.0
+pkgrel=1
+pkgdesc="Bridge between commonmark and pandoc AST"
+url="https://github.com/jgm/commonmark-hs"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-commonmark' 'haskell-commonmark-extensions' 'haskell-pandoc-types')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('c670cb8de8161ddb461992429e271b33004bd4a224d039806b36b0315c5eb06c5e88e3712a0267852a8adcc1a32ef960a9ee04d1ffe65980c7b69b035a10e9ce')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}