[arch-commits] Commit in darcs/repos (2 files)

[Felix Yan]

    Date: Tuesday, August 18, 2020 @ 12:44:52
  Author: felixonmars
Revision: 683896

archrelease: copy trunk to community-staging-x86_64

Added:
  darcs/repos/community-staging-x86_64/
  darcs/repos/community-staging-x86_64/PKGBUILD
    (from rev 683895, darcs/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: darcs/repos/community-staging-x86_64/PKGBUILD (from rev 683895, darcs/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-18 12:44:52 UTC (rev 683896)
@@ -0,0 +1,68 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=darcs
+pkgver=2.16.1
+pkgrel=3
+pkgdesc="A distributed, interactive, smart revision control system"
+url="http://darcs.net"
+license=("GPL")
+arch=('x86_64')
+depends=('curl' 'ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-base16-bytestring'
+         'haskell-conduit' 'haskell-constraints' 'haskell-cryptonite' 'haskell-data-ordlist'
+         'haskell-fgl' 'haskell-hashable' 'haskell-html' 'haskell-http-conduit' 'haskell-http-types'
+         'haskell-knob' 'haskell-memory' 'haskell-mmap' 'haskell-network' 'haskell-network-uri'
+         'haskell-old-time' 'haskell-sandi' 'haskell-regex-applicative' 'haskell-regex-compat-tdfa'
+         'haskell-tar' 'haskell-temporary' 'haskell-unix-compat' 'haskell-utf8-string'
+         'haskell-vector' 'haskell-zip-archive' 'haskell-zlib')
+makedepends=('ghc' 'haskell-cmdargs' 'haskell-findbin' 'haskell-hunit' 'haskell-leancheck'
+             'haskell-quickcheck' 'haskell-shelly' 'haskell-split' 'haskell-test-framework'
+             'haskell-test-framework-hunit' 'haskell-test-framework-leancheck'
+             'haskell-test-framework-quickcheck2')
+checkdepends=('bc' 'time')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('c3c3ee06fc974f14b4d34dfb37993c59654ced23f25428c4542d4852f42cf371afb51dc74435da0953a442b628f86bd745d59a32c3d2a49d33f34d3e99ea156e')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -e 's/^ghc /ghc -dynamic /' \
+        -e 's/ ghc / ghc -dynamic /' \
+        -i tests/*.sh tests/lib
+    sed -i -e 's/< *2.14/<3/' $pkgname.cabal
+
+    # Odd issue...
+    sed -i "s|PACKAGE_VERSION|\"$pkgver\"|" src/hscurl.c
+}
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+        -fcurl -fpkgconfig -f-static -fterminfo -fthreaded -fexecutable \
+        -f-rts -foptimize -f-warn-as-error -f-libiconv
+    LD_LIBRARY_PATH="$srcdir"/$pkgname-$pkgver/dist/build runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+    chmod 644 "${pkgdir}/usr/share/man/man1/darcs.1"
+
+    install -Dm644 contrib/darcs_completion "${pkgdir}/usr/share/bash-completion/completions/darcs"
+    install -Dm644 contrib/_darcs.zsh "${pkgdir}/usr/share/zsh/site-functions/_darcs"
+}