[arch-commits] Commit in haskell-snap-server/repos (2 files)

[Felix Yan]

    Date: Wednesday, August 19, 2020 @ 20:06:21
  Author: felixonmars
Revision: 685197

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-snap-server/repos/community-staging-x86_64/
  haskell-snap-server/repos/community-staging-x86_64/PKGBUILD
    (from rev 685196, haskell-snap-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

Copied: haskell-snap-server/repos/community-staging-x86_64/PKGBUILD (from rev 685196, haskell-snap-server/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-19 20:06:21 UTC (rev 685197)
@@ -0,0 +1,61 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=snap-server
+pkgname=haskell-snap-server
+pkgver=1.1.1.2
+pkgrel=81
+pkgdesc="A web server for the Snap Framework"
+url="https://github.com/snapframework/snap-server"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-case-insensitive'
+         'haskell-clock' 'haskell-io-streams' 'haskell-io-streams-haproxy' 'haskell-lifted-base'
+         'haskell-network' 'haskell-old-locale' 'haskell-snap-core' 'haskell-unix-compat'
+         'haskell-vector')
+makedepends=('ghc')
+checkdepends=('haskell-base16-bytestring' 'haskell-monad-control' 'haskell-random'
+              'haskell-threads' 'haskell-hunit' 'haskell-quickcheck' 'haskell-http-streams'
+              'haskell-http-common' 'haskell-parallel' 'haskell-test-framework'
+              'haskell-test-framework-hunit' 'haskell-test-framework-quickcheck2')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('a11bb92ce8774269704ce8c045bddf4aad15816cfb447453e8010bfce7aff2a08b38d3c99a400ab3882cb9e0b2f0b1f9af69adc56c1b28df53dc3fdd44042e30')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e '/bytestring-builder/d' $_hkgname.cabal
+    echo -e "import Distribution.Simple\nmain = defaultMain" > Setup.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    if (( CHECKFUNC )); then
+        _opts=('--enable-tests')
+    else
+        _opts=('--disable-tests')
+    fi
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname "${_opts[@]}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}