[arch-commits] Commit in haskell-hakyll/repos (2 files)

[Felix Yan]

    Date: Monday, August 24, 2020 @ 03:13:29
  Author: felixonmars
Revision: 687504

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hakyll/repos/community-staging-x86_64/
  haskell-hakyll/repos/community-staging-x86_64/PKGBUILD
    (from rev 687503, haskell-hakyll/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: haskell-hakyll/repos/community-staging-x86_64/PKGBUILD (from rev 687503, haskell-hakyll/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-24 03:13:29 UTC (rev 687504)
@@ -0,0 +1,59 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hakyll
+pkgname=haskell-hakyll
+pkgver=4.13.4.0
+pkgrel=46
+pkgdesc="A static website compiler library"
+url="https://jaspervdj.be/hakyll"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-cryptonite'
+         'haskell-data-default' 'haskell-file-embed' 'haskell-fsnotify' 'haskell-http-conduit'
+         'haskell-http-types' 'haskell-lrucache' 'haskell-memory' 'haskell-network-uri'
+         'haskell-optparse-applicative' 'pandoc' 'pandoc-citeproc' 'haskell-random'
+         'haskell-regex-tdfa' 'haskell-resourcet' 'haskell-scientific' 'haskell-tagsoup'
+         'haskell-time-locale-compat' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-wai' 'haskell-wai-app-static' 'haskell-warp' 'haskell-yaml')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz"
+        hakyll-pandoc-2.10.patch::https://github.com/jaspervdj/hakyll/pull/787.patch)
+sha512sums=('4ade6776cfee7a8293ba4a659cf8633c0e6641ee2c33db9cdddeaca996ff092d027ce4165e174d7acdeb8485904394d9a899351d9e3c065e4ce7cb5af61ee08a'
+            'af8fb00a70ec4461ffb424915c1cc45ccc3d77ac1d36b3680e97363a15bec0ee437c7ce2b9c1e21640117bdbe6cb3fd3b7adccf355cabd942fe7ea2963ee2074')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    patch -p1 -i ../hakyll-pandoc-2.10.patch
+    sed -i 's/< *0.0.12/<1/;s/< *2.14/<3/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fcheckexternal -fwatchserver -fpreviewserver -fusepandoc
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test || warning "https://github.com/jaspervdj/hakyll/issues/682"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}