[arch-commits] Commit in haskell-foldl/repos (2 files)

[Felix Yan]

    Date: Friday, August 28, 2020 @ 14:00:24
  Author: felixonmars
Revision: 690953

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-foldl/repos/community-staging-x86_64/
  haskell-foldl/repos/community-staging-x86_64/PKGBUILD
    (from rev 690952, haskell-foldl/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-foldl/repos/community-staging-x86_64/PKGBUILD (from rev 690952, haskell-foldl/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-28 14:00:24 UTC (rev 690953)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=foldl
+pkgname=haskell-foldl
+pkgver=1.4.8
+pkgrel=7
+pkgdesc="Composable, streaming, and efficient left folds"
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-comonad' 'haskell-contravariant' 'haskell-mwc-random'
+         'haskell-primitive' 'haskell-profunctors' 'haskell-semigroupoids'
+         'haskell-unordered-containers' 'haskell-vector' 'haskell-vector-builder')
+makedepends=('ghc' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('83a0419ce3cd03e5997c450aef150812d2fe64681e65105ac20d904da0fb98c541d5449a1f1a5c61b38763054b6f7fb7bc63f1b7257fbd537ea4bf2b5e0a5dd7')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}