[arch-commits] Commit in stylish-haskell/repos (2 files)

[Felix Yan]

    Date: Saturday, August 29, 2020 @ 05:00:36
  Author: felixonmars
Revision: 691549

archrelease: copy trunk to community-staging-x86_64

Added:
  stylish-haskell/repos/community-staging-x86_64/
  stylish-haskell/repos/community-staging-x86_64/PKGBUILD
    (from rev 691548, stylish-haskell/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: stylish-haskell/repos/community-staging-x86_64/PKGBUILD (from rev 691548, stylish-haskell/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-08-29 05:00:36 UTC (rev 691549)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=stylish-haskell
+pkgver=0.11.0.3
+pkgrel=13
+pkgdesc="Haskell code prettifier"
+url="https://github.com/jaspervdj/stylish-haskell"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-file-embed' 'haskell-optparse-applicative'
+         'haskell-src-exts' 'haskell-strict' 'haskell-syb' 'haskell-hsyaml' 'haskell-hsyaml-aeson')
+makedepends=('ghc' 'haskell-hunit' 'haskell-random' 'haskell-test-framework'
+             'haskell-test-framework-hunit')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('c7ecdc9b464ffa0bef4bac9e89d6ab9de11acd5f19cfb08d86e0e0678a453c9231f474db1449a81e5cc02d5b4fca71f43514df50891151a86c3f1751a62844c7')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -i -e 's/< *3.1/<4/;s/< 0.4/<1/' -e '/semigroups/d' $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-old_base --ghc-option='-pie'
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}