[arch-commits] Commit in srrdb-terminal-client/repos (2 files)

[Justin Kromlinger]

    Date: Sunday, August 30, 2020 @ 17:53:05
  Author: hashworks
Revision: 692848

archrelease: copy trunk to community-x86_64

Added:
  srrdb-terminal-client/repos/community-x86_64/
  srrdb-terminal-client/repos/community-x86_64/PKGBUILD
    (from rev 692847, srrdb-terminal-client/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: srrdb-terminal-client/repos/community-x86_64/PKGBUILD (from rev 692847, srrdb-terminal-client/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2020-08-30 17:53:05 UTC (rev 692848)
@@ -0,0 +1,44 @@
+# Maintainer: hashworks <mail at hashworks.net>
+pkgname=srrdb-terminal-client
+pkgver=1.1.6
+pkgrel=1
+pkgdesc="A terminal client to access srrdb.com"
+arch=("x86_64")
+url="https://github.com/hashworks/srrdb-Terminal-Client"
+license=("GPL3")
+depends=('glibc')
+makedepends=('go')
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
+sha256sums=('e25b486a7915d241c2f53701a277e2a776dbd21ac5e6fd06fa8a54cca44af534')
+
+prepare(){
+	cd "srrdb-Terminal-Client-${pkgver}"
+	mkdir -p build/
+}
+
+build() {
+	cd "srrdb-Terminal-Client-${pkgver}"
+	export CGO_CPPFLAGS="${CPPFLAGS}"
+	export CGO_CFLAGS="${CFLAGS}"
+	export CGO_CXXFLAGS="${CXXFLAGS}"
+	export CGO_LDFLAGS="${LDFLAGS}"
+	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+	go build \
+		-trimpath \
+		-buildmode=pie \
+		-mod=readonly \
+		-modcacherw \
+		-ldflags "-linkmode external -extldflags \"${LDFLAGS}\" -X main.VERSION=\"${pkgver}\" -X main.BUILD_DATE=\"$(date -d@"${SOURCE_DATE_EPOCH}" +"%Y-%m-%d_%H:%M:%S")\"" \
+		-o build .
+}
+
+check() {
+	cd "srrdb-Terminal-Client-${pkgver}"
+	go test .
+}
+
+package() {
+	cd "srrdb-Terminal-Client-${pkgver}"
+	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+	install -Dm755 "build/srrdb-Terminal-Client" "${pkgdir}/usr/bin/srrdb"
+}