[arch-commits] Commit in inkscape/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Wednesday, December 2, 2020 @ 07:53:08
  Author: felixonmars
Revision: 402742

archrelease: copy trunk to staging-x86_64

Added:
  inkscape/repos/staging-x86_64/
  inkscape/repos/staging-x86_64/PKGBUILD
    (from rev 402741, inkscape/trunk/PKGBUILD)

----------+
 PKGBUILD |   71 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

Copied: inkscape/repos/staging-x86_64/PKGBUILD (from rev 402741, inkscape/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-12-02 07:53:08 UTC (rev 402742)
@@ -0,0 +1,71 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+# Contributor: tobias <tobias at archlinux.org>
+
+pkgname=inkscape
+pkgver=1.0.1
+_commit=3bc2e813f584eda88fe02f2a851e66c0168df941
+pkgrel=3
+pkgdesc='Professional vector graphics editor'
+url='https://inkscape.org/'
+license=('GPL' 'LGPL')
+arch=('x86_64')
+makedepends=('cmake' 'boost' 'git')
+
+depends=(
+	'aspell'
+	'dbus-glib'
+	'double-conversion'
+	'gc'
+	'gdl'
+	'gsl'
+	'gtkmm3'
+	'gtkspell3'
+	'libcdr'
+	'libjpeg-turbo'
+	'libmagick6'
+	'libvisio'
+	'libxslt'
+	'poppler-glib'
+	'potrace'
+	'python'
+	'ttf-font'
+)
+
+optdepends=(
+	'fig2dev: xfig input'
+	'gvfs: import clip art'
+	'pstoedit: latex formulas'
+	'python-lxml: some extensions'
+	'python-numpy: some extensions'
+	'scour: optimized SVG output, some extensions'
+	'texlive-core: latex formulas'
+)
+
+#source=("https://media.inkscape.org/dl/resources/file/${pkgname}-${pkgver}.tar.bz2")
+source=("git+https://gitlab.com/inkscape/inkscape.git#commit=${_commit}")
+sha256sums=('SKIP')
+
+prepare() {
+	cd "${srcdir}"
+	cd "${pkgname}"
+	git submodule init
+	git submodule update
+}
+
+build() {
+	cd "${srcdir}"
+	mkdir -p build
+	export PKG_CONFIG_PATH='/usr/lib/imagemagick6/pkgconfig'
+	cmake -H${pkgname} -Bbuild \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_INSTALL_PREFIX:PATH=/usr \
+		-DWITH_DBUS=ON \
+
+	cmake --build build
+}
+
+package() {
+	cd "${srcdir}"
+	DESTDIR="${pkgdir}" cmake --build build --target install
+}