[arch-commits] Commit in htop/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Christian Hesse]

    Date: Monday, December 7, 2020 @ 07:39:22
  Author: eworm
Revision: 403042

archrelease: copy trunk to testing-x86_64

Added:
  htop/repos/testing-x86_64/
  htop/repos/testing-x86_64/PKGBUILD
    (from rev 403041, htop/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: htop/repos/testing-x86_64/PKGBUILD (from rev 403041, htop/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-12-07 07:39:22 UTC (rev 403042)
@@ -0,0 +1,45 @@
+# Maintainer: Christian Hesse <mail at eworm.de>
+# Maintainer: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=htop
+pkgver=3.0.3
+pkgrel=1
+pkgdesc='Interactive process viewer'
+arch=('x86_64')
+url='https://htop.dev/'
+license=('GPL')
+depends=('ncurses' 'libncursesw.so' 'libnl')
+makedepends=('lm_sensors')
+optdepends=('lm_sensors: show cpu temperatures'
+            'lsof: show files opened by a process'
+            'strace: attach to a running process')
+options=('!emptydirs')
+source=("https://github.com/htop-dev/htop/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha256sums=('725103929c925a7252b4dedeb29b3a1da86a2f74e96c50eb9ea6c8fec1942cd2')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+
+  autoreconf -fi
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  ./configure \
+      --prefix=/usr \
+      --sysconfdir=/etc \
+      --enable-cgroup \
+      --enable-delayacct \
+      --enable-openvz \
+      --enable-unicode \
+      --enable-vserver
+
+  make
+}
+
+package() {
+  make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install
+}