[arch-commits] Commit in springlobby/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Sat Dec 12 15:48:09 UTC 2020
Date: Saturday, December 12, 2020 @ 15:48:08
Author: felixonmars
Revision: 773345
archrelease: copy trunk to community-staging-x86_64
Added:
springlobby/repos/community-staging-x86_64/
springlobby/repos/community-staging-x86_64/PKGBUILD
(from rev 773344, springlobby/trunk/PKGBUILD)
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Copied: springlobby/repos/community-staging-x86_64/PKGBUILD (from rev 773344, springlobby/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2020-12-12 15:48:08 UTC (rev 773345)
@@ -0,0 +1,49 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: DuGi <dugi at irc.pl>
+
+pkgname=springlobby
+pkgver=0.270
+pkgrel=4
+pkgdesc="A free cross-platform lobby client for the Spring RTS project"
+arch=('x86_64')
+url="http://springlobby.info/"
+license=('GPL2')
+depends=('hicolor-icon-theme' 'wxgtk3' 'curl' 'libtorrent-rasterbar' 'boost-libs'
+ 'alure' 'libsm')
+optdepends=('sdl' 'sdl_sound' 'sdl_mixer')
+makedepends=('boost' 'cmake' 'git')
+source=("git+https://github.com/springlobby/springlobby.git#tag=$pkgver"
+ https://github.com/springlobby/springlobby/commit/252c4cb156c1442ed9b4faec3f26265bc7c295ff.patch
+ "git+https://github.com/spring/pr-downloader.git")
+sha512sums=('SKIP'
+ '02347b50bf7ac73f128623edc318c534bfda7cd88415f46e6407fc46d4971b5809a7abf608e4c683f6c91879a8c9d399aa982e3c8db99109cc397c64220c2dab'
+ 'SKIP')
+
+prepare() {
+ cd $pkgname
+
+ patch -Np1 -i "${srcdir}"/252c4cb156c1442ed9b4faec3f26265bc7c295ff.patch
+
+ git submodule init
+ git config submodule."src/downloader/lib".url "$srcdir"/pr-downloader
+ git submodule update
+
+ mkdir build
+}
+
+build() {
+ cd $pkgname/build
+
+ cmake .. \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DwxWidgets_CONFIG_EXECUTABLE=/usr/bin/wx-config-gtk3
+ make
+}
+
+package() {
+ cd $pkgname/build
+
+ DESTDIR="$pkgdir" make install
+}
+
+# vim: sw=2:ts=2 et:
More information about the arch-commits
mailing list