[arch-commits] Commit in ledger/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Dec 12 16:16:29 UTC 2020


    Date: Saturday, December 12, 2020 @ 16:16:28
  Author: felixonmars
Revision: 773421

archrelease: copy trunk to community-staging-x86_64

Added:
  ledger/repos/community-staging-x86_64/
  ledger/repos/community-staging-x86_64/PKGBUILD
    (from rev 773419, ledger/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: ledger/repos/community-staging-x86_64/PKGBUILD (from rev 773419, ledger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-12-12 16:16:28 UTC (rev 773421)
@@ -0,0 +1,44 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Maintainer: Ivy Foster <iff at archlinux.org>
+# Contributor: Abdelhakim Qbaich <abdelhakim at qbaich.com>
+# Contributor: korjjj <korjjj+aur at gmail.com>
+# Contributor: TDY <tdy at archlinux.info>
+# Contributor: Adam Ehlers Nyholm Thomsen <adament at gmail.com>
+# Contributor: Nathan Jones <nathanj at insightbb.com>
+
+pkgname=ledger
+pkgver=3.2.1
+pkgrel=4
+pkgdesc='Double-entry accounting system with a command-line reporting interface'
+arch=(i686 x86_64)
+url='https://ledger-cli.org'
+license=(BSD)
+depends=(boost-libs libedit mpfr)
+makedepends=(boost cmake python)
+optdepends=(
+	'emacs: emacs interface'
+	'python: python library'
+)
+source=("ledger-$pkgver.tar.gz::https://github.com/ledger/ledger/archive/v$pkgver.tar.gz")
+sha256sums=('92bf09bc385b171987f456fe3ee9fa998ed5e40b97b3acdd562b663aa364384a')
+
+build() {
+	cd "ledger-$pkgver"
+
+	cmake . \
+		-DCMAKE_INSTALL_PREFIX:PATH=/usr \
+		-DCMAKE_INSTALL_LIBDIR:PATH=lib \
+		-DUSE_PYTHON:BOOL=TRUE
+	make
+}
+
+check() {
+	make -C "ledger-$pkgver" check
+}
+
+package() {
+	cd "ledger-$pkgver"
+
+	make DESTDIR="$pkgdir" install
+	install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/ledger/LICENSE.md"
+}



More information about the arch-commits mailing list