[arch-commits] Commit in haskell-parsers/repos (2 files)

[Felix Yan]

    Date: Sunday, December 13, 2020 @ 14:50:38
  Author: felixonmars
Revision: 774384

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-parsers/repos/community-staging-x86_64/
  haskell-parsers/repos/community-staging-x86_64/PKGBUILD
    (from rev 774383, haskell-parsers/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-parsers/repos/community-staging-x86_64/PKGBUILD (from rev 774383, haskell-parsers/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-12-13 14:50:38 UTC (rev 774384)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=parsers
+pkgname=haskell-parsers
+pkgver=0.12.10
+pkgrel=89
+pkgdesc="Parsing combinators"
+url="https://github.com/ekmett/parsers/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base-orphans' 'haskell-charset'
+         'haskell-scientific' 'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('99ff90de4e60be3c03c8e1e5ae7902a37424c3139ccf566ff1cbc363d176787bd60bb709ef6c56f5b446f1f1b7eca65aa5d431897a0f82a9d6f7fe77fd2ee49f')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}