[arch-commits] Commit in haskell-skylighting-core/repos (2 files)

[Felix Yan]

    Date: Tuesday, December 15, 2020 @ 20:59:09
  Author: felixonmars
Revision: 776210

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-skylighting-core/repos/community-staging-x86_64/
  haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 776209, haskell-skylighting-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD (from rev 776209, haskell-skylighting-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-12-15 20:59:09 UTC (rev 776210)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=skylighting-core
+pkgname=haskell-skylighting-core
+pkgver=0.10.0.1
+pkgrel=7
+pkgdesc="Syntax highlighting library"
+url="https://github.com/jgm/skylighting"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-attoparsec'
+         'haskell-base64-bytestring' 'haskell-blaze-html' 'haskell-case-insensitive'
+         'haskell-colour' 'haskell-hxt' 'haskell-safe' 'haskell-utf8-string')
+makedepends=('ghc' 'haskell-diff' 'haskell-hunit' 'haskell-pretty-show' 'haskell-quickcheck'
+             'haskell-random' 'haskell-tasty' 'haskell-tasty-golden' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('66acdb81f7be9a03fd510e18de3247705854364de3805660a2464e86ccfef969e62c05f7bb1487bf1bb3c864f889860e6e0aac1a5bae1548763c40f29f1a79d6')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fexecutable
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}