[arch-commits] Commit in qtcreator/repos/extra-x86_64 (3 files)

Antonio Rojas arojas at archlinux.org
Thu Dec 17 15:46:29 UTC 2020 

    Date: Thursday, December 17, 2020 @ 15:46:28
  Author: arojas
Revision: 404446

archrelease: copy trunk to extra-x86_64

Added:
  qtcreator/repos/extra-x86_64/PKGBUILD
    (from rev 404445, qtcreator/trunk/PKGBUILD)
Deleted:
  qtcreator/repos/extra-x86_64/PKGBUILD
  qtcreator/repos/extra-x86_64/qtcreator-clang-libs.patch

----------------------------+
 PKGBUILD                   |  126 +++++++++++++++++++------------------------
 qtcreator-clang-libs.patch |   24 --------
 2 files changed, 57 insertions(+), 93 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-12-17 15:46:14 UTC (rev 404445)
+++ PKGBUILD	2020-12-17 15:46:28 UTC (rev 404446)
@@ -1,69 +0,0 @@
-# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
-# Maintainer: Antonio Rojas <arojas at archlinux.org>
-# Contributor: Imanol Celaya <ornitorrincos at archlinux-es.org>
-# Contributor: Lukas Jirkovsky <l.jirkovsky at gmail.com>
-# Contributor: Dan Vratil <progdan at progdansoft.com>
-# Contributor: thotypous <matiasΘarchlinux-br·org>
-# Contributor: delor <bartekpiech gmail com>
-
-pkgname=qtcreator
-pkgver=4.13.3
-_clangver=11.0.0
-pkgrel=1
-pkgdesc='Lightweight, cross-platform integrated development environment'
-arch=(x86_64)
-url='https://www.qt.io'
-license=(LGPL)
-depends=(qt5-tools qt5-quickcontrols qt5-quickcontrols2 qt5-webengine clang=$_clangver qbs clazy syntax-highlighting yaml-cpp desktop-file-utils)
-makedepends=(llvm python)
-options=(docs)
-optdepends=('qt5-doc: integrated Qt documentation'
-            'qt5-examples: welcome page examples'
-            'qt5-translations: for other languages'
-            'gdb: debugger'
-            'cmake: cmake project support'
-            'x11-ssh-askpass: ssh support'
-            'git: git support'
-            'mercurial: mercurial support'
-            'bzr: bazaar support'
-            'valgrind: analyze support'
-            'perf: performer analyzer')
-source=("https://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz"
-        qtcreator-clang-libs.patch)
-sha256sums=('7b0317ca9354284e98967e94a30a1b813db379017d28d9847847498c113df9e5'
-            '0f6d0dc41a87aae9ef371b1950f5b9d823db8b5685c6ac04a7a7ac133eb19a3f')
-
-prepare() {
-  mkdir -p build
-
-  cd qt-creator-opensource-src-$pkgver
-  # fix hardcoded libexec path
-  sed -e 's|libexec\/qtcreator|lib\/qtcreator|g' -i qtcreator.pri
-  sed -e 's|libexec|lib|g' -i src/tools/tools.pro
-  # use system qbs
-  rm -r src/shared/qbs
-
-  # Fix build with clang 10
-  patch -p1 -i ../qtcreator-clang-libs.patch
-}
-
-build() {
-  cd build
-
-  qmake LLVM_INSTALL_DIR=/usr QBS_INSTALL_DIR=/usr \
-    KSYNTAXHIGHLIGHTING_LIB_DIR=/usr/lib KSYNTAXHIGHLIGHTING_INCLUDE_DIR=/usr/include/KF5/KSyntaxHighlighting \
-    CONFIG+=journald QMAKE_CFLAGS_ISYSTEM=-I \
-    DEFINES+=QBS_ENABLE_PROJECT_FILE_UPDATES \
-    "$srcdir"/qt-creator-opensource-src-$pkgver/qtcreator.pro
-  make
-  make docs
-}
-
-package() {
-  cd build
-
-  make INSTALL_ROOT="$pkgdir/usr/" install
-  make INSTALL_ROOT="$pkgdir/usr/" install_docs
-
-  install -Dm644 "$srcdir"/qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
-}

Copied: qtcreator/repos/extra-x86_64/PKGBUILD (from rev 404445, qtcreator/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-12-17 15:46:28 UTC (rev 404446)
@@ -0,0 +1,57 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Imanol Celaya <ornitorrincos at archlinux-es.org>
+# Contributor: Lukas Jirkovsky <l.jirkovsky at gmail.com>
+# Contributor: Dan Vratil <progdan at progdansoft.com>
+# Contributor: thotypous <matiasΘarchlinux-br·org>
+# Contributor: delor <bartekpiech gmail com>
+
+pkgname=qtcreator
+pkgver=4.14.0
+_clangver=11.0.0
+pkgrel=1
+pkgdesc='Lightweight, cross-platform integrated development environment'
+arch=(x86_64)
+url='https://www.qt.io'
+license=(LGPL)
+depends=(qt5-tools qt5-quickcontrols qt5-quickcontrols2 qt5-webengine qt5-svg qt5-quick3d qt5-serialport
+         clang=$_clangver qbs clazy syntax-highlighting yaml-cpp)
+makedepends=(cmake llvm python)
+options=(docs)
+optdepends=('qt5-doc: integrated Qt documentation'
+            'qt5-examples: welcome page examples'
+            'qt5-translations: for other languages'
+            'gdb: debugger'
+            'cmake: cmake project support'
+            'x11-ssh-askpass: ssh support'
+            'git: git support'
+            'mercurial: mercurial support'
+            'bzr: bazaar support'
+            'valgrind: analyze support'
+            'perf: performer analyzer')
+source=("https://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz")
+sha256sums=('d240109351e96446ff149cbd56341ec02ba37bfa50462a85e4d02dfe6b21201e')
+
+prepare() {
+  cd qt-creator-opensource-src-$pkgver
+
+# use system qbs
+  rm -r src/shared/qbs
+# Fix linking to clang
+  sed -e 's|clangFormat|libclang|' -i src/plugins/clangformat/CMakeLists.txt  
+# Fix libexec path
+  sed -e 's|libexec/qtcreator|lib/qtcreator|' -i cmake/QtCreatorAPIInternal.cmake
+}
+
+build() {
+  cmake -B build -S qt-creator-opensource-src-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DWITH_DOCS=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  install -Dm644 qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
+}

Deleted: qtcreator-clang-libs.patch
===================================================================
--- qtcreator-clang-libs.patch	2020-12-17 15:46:14 UTC (rev 404445)
+++ qtcreator-clang-libs.patch	2020-12-17 15:46:28 UTC (rev 404446)
@@ -1,24 +0,0 @@
-diff --git a/src/shared/clang/clang_installation.pri b/src/shared/clang/clang_installation.pri
-index 08838838bc..bee3779484 100644
---- a/src/shared/clang/clang_installation.pri
-+++ b/src/shared/clang/clang_installation.pri
-@@ -131,9 +131,7 @@ defineReplace(extractWarnings) {
-     return($$result)
- }
- 
--CLANGTOOLING_LIBS=-lclangTooling -lclangIndex -lclangFrontend -lclangParse -lclangSerialization \
--                  -lclangSema -lclangEdit -lclangAnalysis -lclangDriver -lclangDynamicASTMatchers \
--                  -lclangASTMatchers -lclangToolingCore -lclangAST -lclangLex -lclangBasic
-+CLANGTOOLING_LIBS=-lclang-cpp
- win32:CLANGTOOLING_LIBS += -lversion
- 
- BIN_EXTENSION =
-@@ -207,7 +205,7 @@ isEmpty(LLVM_VERSION) {
-     isEmpty(QTC_CLANG_BUILDMODE_MISMATCH)|!equals(QTC_CLANG_BUILDMODE_MISMATCH, 1) {
-         CLANGFORMAT_MAIN_HEADER = $$LLVM_INCLUDEPATH/clang/Format/Format.h
-         exists($$CLANGFORMAT_MAIN_HEADER) {
--            CLANGFORMAT_LIBS=-lclangFormat -lclangToolingInclusions -lclangToolingCore -lclangRewrite -lclangLex -lclangBasic
-+            CLANGFORMAT_LIBS=-lclang-cpp
-             ALL_CLANG_LIBS=-lclangFormat -lclangToolingInclusions -lclangTooling -lclangToolingCore \
-                            -lclangRewrite -lclangIndex -lclangFrontend -lclangParse -lclangSerialization \
-                            -lclangSema -lclangEdit -lclangAnalysis -lclangDriver -lclangDynamicASTMatchers \

More information about the arch-commits mailing list