[arch-commits] Commit in haskell-tidal/repos (2 files)

[Felix Yan]

    Date: Thursday, December 17, 2020 @ 20:04:31
  Author: felixonmars
Revision: 777960

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tidal/repos/community-staging-x86_64/
  haskell-tidal/repos/community-staging-x86_64/PKGBUILD
    (from rev 777959, haskell-tidal/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: haskell-tidal/repos/community-staging-x86_64/PKGBUILD (from rev 777959, haskell-tidal/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-12-17 20:04:31 UTC (rev 777960)
@@ -0,0 +1,54 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=Tidal
+pkgname=haskell-tidal
+pkgver=1.6.1
+pkgrel=32
+pkgdesc="A domain specific language for live coding pattern."
+arch=('x86_64')
+url="https://tidalcycles.org/"
+license=('GPL3')
+groups=('pro-audio')
+depends=('ghc' 'ghc-libs' 'glibc' 'haskell-bifunctors' 'haskell-clock'
+'haskell-colour' 'haskell-hosc' 'haskell-mwc-random' 'haskell-network'
+'haskell-primitive' 'haskell-random' 'haskell-vector' 'supercollider')
+checkdepends=('haskell-microspec')
+optdepends=('sc3-plugins: Examples using special UGens')
+conflicts=('tidalcycles')
+replaces=('tidalcycles')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/tidalcycles/${_name}/archive/${pkgver}.tar.gz")
+sha512sums=('3c94418b317e21219e91cb58081e0598c75fb8ab71203f2b3a71cf0762067634705a26d62443077ba7ec266141ad3f18ab4958091ebe357e1597e00b7e3ad938')
+
+prepare() {
+  mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  runhaskell Setup configure -O \
+                             --enable-shared \
+                             --enable-executable-dynamic \
+                             --disable-library-vanilla \
+                             --prefix=/usr \
+                             --docdir="/usr/share/doc/${pkgname}" \
+                             --enable-tests \
+                             --dynlibdir=/usr/lib \
+                             --libsubdir=\$compiler/site-local/\$pkgid
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  runhaskell Setup test
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  runhaskell Setup copy --destdir="${pkgdir}"
+  install -vDm 744 register.sh "$pkgdir/usr/share/haskell/register/$pkgname.sh"
+  install -vDm 744 unregister.sh "$pkgdir/usr/share/haskell/unregister/$pkgname.sh"
+}