[arch-commits] Commit in nodejs-lts-fermium/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Sat Dec 19 06:09:42 UTC 2020
Date: Saturday, December 19, 2020 @ 06:09:42
Author: foutrelis
Revision: 779746
archrelease: copy trunk to community-staging-x86_64
Added:
nodejs-lts-fermium/repos/community-staging-x86_64/
nodejs-lts-fermium/repos/community-staging-x86_64/PKGBUILD
(from rev 779745, nodejs-lts-fermium/trunk/PKGBUILD)
----------+
PKGBUILD | 59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 59 insertions(+)
Copied: nodejs-lts-fermium/repos/community-staging-x86_64/PKGBUILD (from rev 779745, nodejs-lts-fermium/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2020-12-19 06:09:42 UTC (rev 779746)
@@ -0,0 +1,59 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=nodejs-lts-fermium
+pkgver=14.15.1
+pkgrel=2
+pkgdesc="Evented I/O for V8 javascript (LTS release: Fermium)"
+arch=(x86_64)
+url="https://nodejs.org/"
+license=(MIT)
+depends=(openssl zlib icu libuv c-ares brotli libnghttp2) # http-parser
+makedepends=(python procps-ng)
+optdepends=('npm: nodejs package manager')
+provides=("nodejs=$pkgver")
+conflicts=(nodejs)
+source=("${url}/dist/v${pkgver}/node-v${pkgver}.tar.xz")
+# https://nodejs.org/download/release/latest-fermium/SHASUMS256.txt.asc
+sha256sums=(0161436846f7578938ad87af197e0cf112452232723227f88d5a0efc34dec1bc)
+validpgpkeys=(C4F0DFFF4E8C1A8236409D08E73BC641CC11F4C8 # Myles Borins <mylesborins at google.com>
+ 77984A986EBC2AA786BC0F66B01FBB92821C587A # Gibson Fahnestock <gibfahn at gmail.com>
+ B9AE9905FFD7803F25714661B63B535A4C206CA9 # Evan Lucas <evanlucas at me.com>
+ DD8F2338BAE7501E3DD5AC78C273792F7D83545D # Rod Vagg <rod at vagg.org>
+ B9E2F5981AA6E0CD28160D9FF13993A75599653C # Shelley Vohr <shelley.vohr at gmail.com>
+ 4ED778F539E3634C779C87C6D7062848A1AB005C # Beth Griggs <Bethany.Griggs at uk.ibm.com>
+ C82FA3AE1CBEDC6BE46B9360C43CEC45C17AB93C) # Richard Lau <rlau at redhat.com>
+
+
+build() {
+ cd node-v${pkgver}
+
+ ./configure \
+ --prefix=/usr \
+ --with-intl=system-icu \
+ --without-npm \
+ --shared-openssl \
+ --shared-zlib \
+ --shared-libuv \
+ --experimental-http-parser \
+ --shared-cares \
+ --shared-brotli \
+ --shared-nghttp2
+ # --shared-v8
+ # --shared-http-parser
+
+ make
+}
+
+check() {
+ cd node-v${pkgver}
+ # https://github.com/nodejs/node/issues/32765
+ sed -i '/\$(MAKE) -s test-doc/d' Makefile
+ make test
+}
+
+package() {
+ cd node-v${pkgver}
+ make DESTDIR="${pkgdir}" install
+ install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}
More information about the arch-commits
mailing list