[arch-commits] Commit in qt6-base/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Saturday, December 19, 2020 @ 08:21:01
  Author: felixonmars
Revision: 404572

archrelease: copy trunk to staging-x86_64

Added:
  qt6-base/repos/staging-x86_64/
  qt6-base/repos/staging-x86_64/PKGBUILD
    (from rev 404571, qt6-base/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: qt6-base/repos/staging-x86_64/PKGBUILD (from rev 404571, qt6-base/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-12-19 08:21:01 UTC (rev 404572)
@@ -0,0 +1,55 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=qt6-base
+_qtver=6.0.0
+pkgver=${_qtver/-/}
+pkgrel=2
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='A cross-platform application and UI framework'
+depends=(libjpeg-turbo xcb-util-keysyms xcb-util-cursor libgl fontconfig xdg-utils
+         shared-mime-info xcb-util-wm libxrender libxi sqlite mesa
+         tslib libinput libxkbcommon-x11 libproxy libcups double-conversion brotli libb2) # md4c - not supported yet
+makedepends=(cmake libfbclient mariadb-libs unixodbc postgresql alsa-lib gst-plugins-base-libs
+             gtk3 libpulse cups freetds vulkan-headers xmlstarlet)
+optdepends=('postgresql-libs: PostgreSQL driver'
+            'mariadb-libs: MariaDB driver'
+            'unixodbc: ODBC driver'
+            'libfbclient: Firebird/iBase driver'
+            'freetds: MS SQL driver'
+            'gtk3: GTK platform plugin'
+            'perl: for syncqt')
+groups=(qt6)
+_pkgfn="${pkgname/6-/}-everywhere-src-${_qtver}"
+source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz")
+sha256sums=('ae227180272d199cbb15318e3353716afada5c57fd5185b812ae26912c958656')
+
+build() {
+  cmake -B build -S $_pkgfn \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DINSTALL_BINDIR=lib/qt6/bin \
+    -DINSTALL_DOCDIR=share/doc/qt6 \
+    -DINSTALL_ARCHDATADIR=lib/qt6 \
+    -DINSTALL_DATADIR=share/qt6 \
+    -DINSTALL_INCLUDEDIR=include/qt6 \
+    -DINSTALL_MKSPECSDIR=lib/qt6/mkspecs \
+    -DINSTALL_EXAMPLESDIR=share/doc/qt6/examples \
+    -DQT_FEATURE_journald=ON \
+    -DQT_FEATURE_openssl_linked=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  install -Dm644 $_pkgfn/LICENSE* -t "$pkgdir"/usr/share/licenses/$pkgbase
+
+  # Symlinks for backwards compatibility
+  mkdir -p "$pkgdir"/usr/bin
+  for _b in $(ls "$pkgdir"/usr/lib/qt6/bin); do
+    ln -rs "$pkgdir"/usr/lib/qt6/bin/$_b "$pkgdir"/usr/bin/$_b-qt6
+  done
+}