[arch-commits] Commit in kdb/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Evangelos Foutras
foutrelis at archlinux.org
Sat Dec 19 10:01:55 UTC 2020
Date: Saturday, December 19, 2020 @ 10:01:55
Author: foutrelis
Revision: 404600
archrelease: copy trunk to staging-x86_64
Added:
kdb/repos/staging-x86_64/
kdb/repos/staging-x86_64/PKGBUILD
(from rev 404599, kdb/trunk/PKGBUILD)
----------+
PKGBUILD | 37 +++++++++++++++++++++++++++++++++++++
1 file changed, 37 insertions(+)
Copied: kdb/repos/staging-x86_64/PKGBUILD (from rev 404599, kdb/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2020-12-19 10:01:55 UTC (rev 404600)
@@ -0,0 +1,37 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=kdb
+pkgver=3.2.0
+pkgrel=6
+pkgdesc="A database connectivity and creation framework for various database vendors"
+arch=(x86_64)
+url="http://www.kexi-project.org/"
+license=(GPL2)
+depends=(kcoreaddons)
+makedepends=(extra-cmake-modules python mariadb-libs postgresql qt5-tools doxygen qt5-doc)
+optdepends=('mariadb-libs: MySQL plugin' 'postgresql: PostgreSQL plugin')
+source=("https://download.kde.org/stable/$pkgname/src/$pkgname-$pkgver.tar.xz"{,.sig}
+ kdb-postgresql-12.patch::"https://invent.kde.org/libraries/kdb/-/commit/40cdaea4.patch"
+ kdb-mkspecs-path.patch::"https://invent.kde.org/libraries/kdb/-/merge_requests/6.patch")
+sha256sums=('8f8983bc8d143832dc14bc2003ba6af1af27688e477c0c791fd61445464f2069'
+ 'SKIP'
+ '7c67b4b349432cbe44413758dcd020600eca1366c82fb2d02c361dbf66e8d0f7'
+ '2efccec64624d2d38b40f13ae6a508439e0f90330d5124c884c16fce461a2988')
+validpgpkeys=(4866BAF713B465677A4059643C7C0E201B6524DB) # Jarosław Staniek <staniek at kde.org>
+
+
+prepare() {
+ patch -d $pkgname-$pkgver -p1 -i ../kdb-postgresql-12.patch # Fix build with postgresql 12
+ patch -d $pkgname-$pkgver -p1 -i ../kdb-mkspecs-path.patch # Fix mkspecs install dir
+}
+
+build() {
+ cmake -B build -S $pkgname-$pkgver \
+ -DBUILD_TESTING=OFF \
+ -DBUILD_QCH=ON
+ cmake --build build
+}
+
+package() {
+ DESTDIR="$pkgdir" cmake --install build
+}
More information about the arch-commits
mailing list