[arch-commits] Commit in haskell-kan-extensions/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon Dec 21 16:00:02 UTC 2020


    Date: Monday, December 21, 2020 @ 16:00:02
  Author: felixonmars
Revision: 781185

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-kan-extensions/repos/community-staging-x86_64/
  haskell-kan-extensions/repos/community-staging-x86_64/PKGBUILD
    (from rev 781184, haskell-kan-extensions/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: haskell-kan-extensions/repos/community-staging-x86_64/PKGBUILD (from rev 781184, haskell-kan-extensions/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-12-21 16:00:02 UTC (rev 781185)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=kan-extensions
+pkgname=haskell-kan-extensions
+pkgver=5.2.1
+pkgrel=21
+pkgdesc="Kan extensions, Kan lifts, the Yoneda lemma, and (co)density (co)monads"
+url="https://github.com/ekmett/kan-extensions/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-adjunctions' 'haskell-comonad' 'haskell-contravariant'
+         'haskell-distributive' 'haskell-free' 'haskell-invariant' 'haskell-profunctors'
+         'haskell-semigroupoids' 'haskell-tagged' 'haskell-transformers-compat')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('671cec5774c7df978810ede9eda0aa373e6fcc1b1d892bb7b490c433fbf618ab655c07d4be5ea5cc54636306b7faee1091f481dc6f0c46de1abddf927a0a2056')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list