[arch-commits] Commit in nextcloud-client/repos/community-testing-x86_64 (2 files)
Chih-Hsuan Yen
yan12125 at archlinux.org
Wed Dec 23 17:30:41 UTC 2020
Date: Wednesday, December 23, 2020 @ 17:30:40
Author: yan12125
Revision: 784992
archrelease: copy trunk to community-testing-x86_64
Added:
nextcloud-client/repos/community-testing-x86_64/PKGBUILD
(from rev 784991, nextcloud-client/trunk/PKGBUILD)
Deleted:
nextcloud-client/repos/community-testing-x86_64/PKGBUILD
----------+
PKGBUILD | 176 ++++++++++++++++++++++++++++++-------------------------------
1 file changed, 88 insertions(+), 88 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2020-12-23 17:30:27 UTC (rev 784991)
+++ PKGBUILD 2020-12-23 17:30:40 UTC (rev 784992)
@@ -1,88 +0,0 @@
-# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
-# Contributor: Tyler Dence <tyzoid at archlinux32.org>
-# Contributor: Konstantin Shalygin <k0ste at k0ste.ru>
-
-pkgbase=nextcloud-client
-pkgname=(nextcloud-client nextcloud-client-cloudproviders)
-# Upstream does not provide signed tarballs (yet)
-# https://github.com/nextcloud/desktop/issues/1510
-pkgver=3.1.0
-pkgrel=1
-arch=(x86_64)
-url='https://nextcloud.com/'
-license=(GPL)
-makedepends=(libcloudproviders openssl sqlite
- qt5-quickcontrols2 qt5-svg qt5-tools qt5-webengine qtkeychain
- extra-cmake-modules kio
- cmocka doxygen git python-sphinx)
-source=("$pkgbase::git+https://github.com/nextcloud/desktop.git?signed#tag=v$pkgver")
-validpgpkeys=(
- A26B951528EA1BA1678C7AE5D406C75CEE1A36D6 # one of keys controlled by github.com/camilasan
- 42E775EAA3E47F9E0D5CDB0E00819E3BF4177B28 # controlled by github.com/misch7
- 17166A5275C5FA6F1A48FD78074BBBCB8DECC9E2 # https://github.com/er-vin.gpg
-)
-sha256sums=('SKIP')
-
-prepare() {
- # tmpdir for check()
- mkdir tmpdir
-
- # Use system GNUInstallDirs.cmake so that we can benefit from
- # https://gitlab.kitware.com/cmake/cmake/merge_requests/3735
- rm -v $pkgbase/cmake/modules/GNUInstallDirs.cmake
-}
-
-build() {
- cd $pkgbase
-
- # bundled breakpad in libcrashreporter-qt submodule is too old and does not build with glibc >= 2.26
- # Upstream fix: https://github.com/google/breakpad/commit/bddcc58860f522a0d4cbaa7e9d04058caee0db9d
- cmake -B build -S . \
- -DCMAKE_BUILD_TYPE=None \
- -DCMAKE_INSTALL_PREFIX=/usr \
- -DNO_SHIBBOLETH=1 \
- -DWITH_CRASHREPORTER=OFF \
- -DUNIT_TESTING=ON
-
- # TODO: fix installation of PDF and HTML documents
- # WIP at https://github.com/yan12125/desktop/tree/doc-install-path
- make -C build all doc-man
-}
-
-check() {
- cd $pkgbase/build
-
- # Tests fail if $TMPDIR is too small; specify an alternative for machines
- # with a small /tmp partition.
- TMPDIR="$srcdir/tmpdir" make test
-}
-
-package_nextcloud-client() {
- pkgdesc='Nextcloud desktop client'
- depends=(openssl sqlite qtkeychain qt5-svg qt5-webengine xdg-utils libcloudproviders
- qt5-graphicaleffects qt5-quickcontrols2)
- optdepends=(
- 'kio: integration with Dolphin'
- 'nemo-python: integration with Nemo'
- 'python-nautilus: integration with Nautilus'
- 'python-caja: integration with Caja'
- 'nextcloud-client-cloudproviders: cloudproviders support'
- )
- backup=('etc/Nextcloud/sync-exclude.lst')
-
- cd $pkgbase/build
-
- make DESTDIR="$pkgdir" install
-
- rm -v "$pkgdir"/usr/share/cloud-providers/com.nextcloudgmbh.Nextcloud.ini
- rm -v "$pkgdir"/usr/share/dbus-1/services/com.nextcloudgmbh.Nextcloud.service
- cd "$pkgdir"/usr/share && rmdir -p cloud-providers dbus-1/services
-}
-
-package_nextcloud-client-cloudproviders() {
- pkgdesc='cloudproviders support for the Nextcloud desktop client'
- depends=(nextcloud-client)
-
- cd $pkgbase/build
- make -C shell_integration/libcloudproviders DESTDIR="$pkgdir" install
-}
Copied: nextcloud-client/repos/community-testing-x86_64/PKGBUILD (from rev 784991, nextcloud-client/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2020-12-23 17:30:40 UTC (rev 784992)
@@ -0,0 +1,88 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Contributor: Tyler Dence <tyzoid at archlinux32.org>
+# Contributor: Konstantin Shalygin <k0ste at k0ste.ru>
+
+pkgbase=nextcloud-client
+pkgname=(nextcloud-client nextcloud-client-cloudproviders)
+# Upstream does not provide signed tarballs (yet)
+# https://github.com/nextcloud/desktop/issues/1510
+pkgver=3.1.1
+pkgrel=1
+arch=(x86_64)
+url='https://nextcloud.com/'
+license=(GPL)
+makedepends=(libcloudproviders openssl sqlite
+ qt5-quickcontrols2 qt5-svg qt5-tools qt5-webengine qtkeychain
+ extra-cmake-modules kio
+ cmocka doxygen git python-sphinx)
+source=("$pkgbase::git+https://github.com/nextcloud/desktop.git?signed#tag=v$pkgver")
+validpgpkeys=(
+ A26B951528EA1BA1678C7AE5D406C75CEE1A36D6 # one of keys controlled by github.com/camilasan
+ 42E775EAA3E47F9E0D5CDB0E00819E3BF4177B28 # controlled by github.com/misch7
+ 17166A5275C5FA6F1A48FD78074BBBCB8DECC9E2 # https://github.com/er-vin.gpg
+)
+sha256sums=('SKIP')
+
+prepare() {
+ # tmpdir for check()
+ mkdir tmpdir
+
+ # Use system GNUInstallDirs.cmake so that we can benefit from
+ # https://gitlab.kitware.com/cmake/cmake/merge_requests/3735
+ rm -v $pkgbase/cmake/modules/GNUInstallDirs.cmake
+}
+
+build() {
+ cd $pkgbase
+
+ # bundled breakpad in libcrashreporter-qt submodule is too old and does not build with glibc >= 2.26
+ # Upstream fix: https://github.com/google/breakpad/commit/bddcc58860f522a0d4cbaa7e9d04058caee0db9d
+ cmake -B build -S . \
+ -DCMAKE_BUILD_TYPE=None \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DNO_SHIBBOLETH=1 \
+ -DWITH_CRASHREPORTER=OFF \
+ -DUNIT_TESTING=ON
+
+ # TODO: fix installation of PDF and HTML documents
+ # WIP at https://github.com/yan12125/desktop/tree/doc-install-path
+ make -C build all doc-man
+}
+
+check() {
+ cd $pkgbase/build
+
+ # Tests fail if $TMPDIR is too small; specify an alternative for machines
+ # with a small /tmp partition.
+ TMPDIR="$srcdir/tmpdir" make test
+}
+
+package_nextcloud-client() {
+ pkgdesc='Nextcloud desktop client'
+ depends=(openssl sqlite qtkeychain qt5-svg qt5-webengine xdg-utils libcloudproviders
+ qt5-graphicaleffects qt5-quickcontrols2)
+ optdepends=(
+ 'kio: integration with Dolphin'
+ 'nemo-python: integration with Nemo'
+ 'python-nautilus: integration with Nautilus'
+ 'python-caja: integration with Caja'
+ 'nextcloud-client-cloudproviders: cloudproviders support'
+ )
+ backup=('etc/Nextcloud/sync-exclude.lst')
+
+ cd $pkgbase/build
+
+ make DESTDIR="$pkgdir" install
+
+ rm -v "$pkgdir"/usr/share/cloud-providers/com.nextcloudgmbh.Nextcloud.ini
+ rm -v "$pkgdir"/usr/share/dbus-1/services/com.nextcloudgmbh.Nextcloud.service
+ cd "$pkgdir"/usr/share && rmdir -p cloud-providers dbus-1/services
+}
+
+package_nextcloud-client-cloudproviders() {
+ pkgdesc='cloudproviders support for the Nextcloud desktop client'
+ depends=(nextcloud-client)
+
+ cd $pkgbase/build
+ make -C shell_integration/libcloudproviders DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list