[arch-commits] Commit in haskell-vty/repos (2 files)

[Felix Yan]

    Date: Thursday, December 24, 2020 @ 07:08:45
  Author: felixonmars
Revision: 786668

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-vty/repos/community-staging-x86_64/
  haskell-vty/repos/community-staging-x86_64/PKGBUILD
    (from rev 786667, haskell-vty/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-vty/repos/community-staging-x86_64/PKGBUILD (from rev 786667, haskell-vty/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-12-24 07:08:45 UTC (rev 786668)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=vty
+pkgname=haskell-vty
+pkgver=5.32
+pkgrel=10
+pkgdesc="A simple terminal UI library"
+url="https://github.com/jtdaugherty/vty"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-blaze-builder' 'haskell-microlens'
+         'haskell-microlens-mtl' 'haskell-microlens-th' 'haskell-hashable' 'haskell-parallel'
+         'haskell-utf8-string' 'haskell-vector')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-smallcheck'
+             'haskell-quickcheck-assertions' 'haskell-test-framework'
+             'haskell-test-framework-smallcheck' 'haskell-test-framework-hunit' 'haskell-random'
+             'haskell-string-qq')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('bd7a59d3c1336d045b7abab4b4c02ecba5d88617189a0a4ef7bd03609e6590d365fca297db827d709075f56c79b83e5fc020f7d6156b1e98a450fe2dafb06f6e')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    # https://github.com/jtdaugherty/vty/issues/132
+    # https://github.com/haskell/cabal/issues/4918
+    cd $_hkgname-$pkgver
+    # runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}