[arch-commits] Commit in (5 files)
Brett Cornwall
ainola at archlinux.org
Fri Dec 25 22:41:28 UTC 2020
Date: Friday, December 25, 2020 @ 22:41:28
Author: ainola
Revision: 791060
Add interception-tools (20 votes in AUR)
This package includes helpful replacement functionality for xcape, which is no
longer usable in wayland sessions.
Added:
interception-tools/
interception-tools/repos/
interception-tools/trunk/
interception-tools/trunk/PKGBUILD
interception-tools/trunk/udevmon.service
-----------------+
PKGBUILD | 36 ++++++++++++++++++++++++++++++++++++
udevmon.service | 36 ++++++++++++++++++++++++++++++++++++
2 files changed, 72 insertions(+)
Added: interception-tools/trunk/PKGBUILD
===================================================================
--- interception-tools/trunk/PKGBUILD (rev 0)
+++ interception-tools/trunk/PKGBUILD 2020-12-25 22:41:28 UTC (rev 791060)
@@ -0,0 +1,36 @@
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+# Contributor: Francisco Lopes
+
+pkgname=interception-tools
+pkgver=0.2.2
+pkgrel=2
+pkgdesc='A minimal composable infrastructure on top of libudev and libevdev'
+arch=('x86_64')
+license=('GPL3')
+url='https://gitlab.com/interception/linux/tools'
+depends=('libevdev' 'yaml-cpp' 'systemd-libs')
+makedepends=('cmake' 'systemd')
+# Until https://gitlab.com/interception/linux/tools/-/merge_requests/10 is
+# merged, include a .service file ourselves
+source=("$pkgname-$pkgver.tar.gz::https://gitlab.com/interception/linux/tools/-/archive/v$pkgver/tools-v$pkgver.tar.gz"
+ 'udevmon.service')
+sha256sums=('56fc110917b05b7ec00b440436fd536a30275449e574978a72bb1f102e9a731a'
+ '862b629a8b3f3b1a5ce7e916994fbcbc3d8891d41707c3e2497c434bdc238ee9')
+
+build() {
+ cmake -B build \
+ -S "tools-v${pkgver}" \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=None \
+ -Wno-dev
+ cmake --build build
+}
+
+package() {
+ install -dm755 "$pkgdir/etc/interception/udevmon.d"
+ install -Dm644 udevmon.service -t "$pkgdir/usr/lib/systemd/system"
+ install -Dm644 "tools-v${pkgver}/README.md" -t "$pkgdir/usr/share/doc/$pkgname"
+
+ cd build
+ make DESTDIR="$pkgdir/" install
+}
Added: interception-tools/trunk/udevmon.service
===================================================================
--- interception-tools/trunk/udevmon.service (rev 0)
+++ interception-tools/trunk/udevmon.service 2020-12-25 22:41:28 UTC (rev 791060)
@@ -0,0 +1,36 @@
+[Unit]
+Description=Monitor input devices for launching tasks
+Wants=systemd-udev-settle.service
+After=systemd-udev-settle.service
+Documentation=man:udev(7)
+
+[Service]
+ExecStart=/usr/bin/udevmon -c /etc/interception/udevmon.yaml
+Nice=-20
+Restart=on-failure
+RestartSec=5s
+OOMScoreAdjust=-1000
+
+DeviceAllow=char-* rw
+DevicePolicy=strict
+IPAddressDeny=any
+LockPersonality=yes
+MemoryDenyWriteExecute=yes
+PrivateMounts=yes
+PrivateTmp=true
+ProtectControlGroups=true
+ProtectHome=true
+ProtectHostname=yes
+ProtectKernelLogs=true
+ProtectKernelModules=true
+ProtectKernelTunables=true
+ProtectSystem=strict
+RestrictAddressFamilies=AF_UNIX AF_NETLINK AF_INET AF_INET6
+RestrictNamespaces=true
+RestrictRealtime=true
+RestrictSUIDSGID=yes
+SystemCallErrorNumber=EPERM
+SystemCallFilter=@system-service @raw-io
+
+[Install]
+WantedBy=multi-user.target
More information about the arch-commits
mailing list