[arch-commits] Commit in haskell-persistent/repos (2 files)

[Felix Yan]

    Date: Saturday, December 26, 2020 @ 05:58:45
  Author: felixonmars
Revision: 792060

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent/repos/community-staging-x86_64/
  haskell-persistent/repos/community-staging-x86_64/PKGBUILD
    (from rev 792059, haskell-persistent/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-persistent/repos/community-staging-x86_64/PKGBUILD (from rev 792059, haskell-persistent/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-12-26 05:58:45 UTC (rev 792060)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=persistent
+pkgname=haskell-persistent
+pkgver=2.11.0.2
+pkgrel=8
+pkgdesc="Type-safe, multi-backend data serialization"
+url="http://www.yesodweb.com/book/persistent"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-base64-bytestring'
+         'haskell-blaze-html' 'haskell-conduit' 'haskell-fast-logger' 'haskell-http-api-data'
+         'haskell-monad-logger' 'haskell-path-pieces' 'haskell-resource-pool' 'haskell-resourcet'
+         'haskell-scientific' 'haskell-silently' 'haskell-unordered-containers'
+         'haskell-unliftio' 'haskell-unliftio-core' 'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-shakespeare')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('bba29f0812e1c1a94c224c3e48377e3b8ea35d43e3954fc48012791db50f42e9c4302da58060ac717524d7d0cb1da8f7152e0acb9afb93ce89ff862fa568b675')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-nooverlap
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}