[arch-commits] Commit in haskell-persistent-qq/repos (2 files)

[Felix Yan]

    Date: Tuesday, December 29, 2020 @ 13:18:52
  Author: felixonmars
Revision: 797075

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent-qq/repos/community-staging-x86_64/
  haskell-persistent-qq/repos/community-staging-x86_64/PKGBUILD
    (from rev 797074, haskell-persistent-qq/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-persistent-qq/repos/community-staging-x86_64/PKGBUILD (from rev 797074, haskell-persistent-qq/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-12-29 13:18:52 UTC (rev 797075)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=persistent-qq
+pkgname=haskell-persistent-qq
+pkgver=2.9.2.1
+pkgrel=20
+pkgdesc="Provides a quasi-quoter for raw SQL for persistent"
+url="https://github.com/yesod-web/persistent"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-src-meta' 'haskell-persistent')
+makedepends=('ghc' 'haskell-aeson' 'haskell-fast-logger' 'haskell-hspec' 'haskell-hunit'
+             'haskell-monad-logger' 'haskell-persistent-sqlite' 'haskell-persistent-template'
+             'haskell-resourcet' 'haskell-unliftio')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('d93bf08c64ef0454f0c956e393a39df4e1facceb25b010badb4305629f2dcd4157ef32735d7feed9aca90bd6e5f09a0ade723cfd6d60324ea842d4b54bacbcad')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    if (( CHECKFUNC )); then
+        _opts=('--enable-tests')
+    else
+        _opts=('--disable-tests')
+    fi
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname "${_opts[@]}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}