[arch-commits] Commit in ibus-chewing/repos (2 files)

[Chih-Hsuan Yen]

    Date: Tuesday, December 29, 2020 @ 14:31:55
  Author: yan12125
Revision: 797155

archrelease: copy trunk to community-testing-x86_64

Added:
  ibus-chewing/repos/community-testing-x86_64/
  ibus-chewing/repos/community-testing-x86_64/PKGBUILD
    (from rev 797154, ibus-chewing/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: ibus-chewing/repos/community-testing-x86_64/PKGBUILD (from rev 797154, ibus-chewing/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-12-29 14:31:55 UTC (rev 797155)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Rainy <rainylau(at)gmail(dot)com>
+# Contributor: Lee.MaRS <leemars at gmail.com>
+# Contributor: Hiroshi Yui <hiroshiyui at gmail.com>
+
+pkgname=ibus-chewing
+pkgver=1.6.1+12+gc1e7f0d
+_commit=c1e7f0d97aa8bb1a1166621c3f0780daa0db06c1
+pkgrel=1
+pkgdesc='Chinese Chewing Engine for IBus Framework'
+arch=('x86_64')
+license=('GPL')
+url='https://github.com/definite/ibus-chewing'
+depends=('ibus' 'libchewing' 'libxtst' 'gtk3')
+makedepends=('swig' 'gob2' 'cmake-fedora' 'git')
+source=("git+https://github.com/definite/ibus-chewing.git#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --always | sed 's/-/+/g'
+}
+
+build() {
+  cd $pkgname
+
+  cmake -B build -S . \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DLIBEXEC_DIR=/usr/lib/ibus
+
+  # XXX: updated *.po files contain no translated strings. Maybe because fedora.zanata.org is down
+  # https://github.com/definite/ibus-chewing/issues/150
+  touch build/po/ibus-chewing.pot
+  cp -v po/*.po build/po/
+
+  make -C build
+}
+
+package() {
+  cd $pkgname/build
+  make DESTDIR="$pkgdir" install
+}