[arch-commits] Commit in (4 files)
Chih-Hsuan Yen
yan12125 at archlinux.org
Sat Feb 1 05:22:26 UTC 2020
Date: Saturday, February 1, 2020 @ 05:22:26
Author: yan12125
Revision: 560983
addpkg: python-sphinx-jinja, dependency of upcoming buildbot-docs
Added:
python-sphinx-jinja/
python-sphinx-jinja/repos/
python-sphinx-jinja/trunk/
python-sphinx-jinja/trunk/PKGBUILD
----------+
PKGBUILD | 31 +++++++++++++++++++++++++++++++
1 file changed, 31 insertions(+)
Added: python-sphinx-jinja/trunk/PKGBUILD
===================================================================
--- python-sphinx-jinja/trunk/PKGBUILD (rev 0)
+++ python-sphinx-jinja/trunk/PKGBUILD 2020-02-01 05:22:26 UTC (rev 560983)
@@ -0,0 +1,31 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+
+pkgname=python-sphinx-jinja
+pkgver=1.1.1
+pkgrel=1
+pkgdesc='A sphinx extension to include jinja based templates based documentation into a sphinx doc'
+arch=(any)
+url='https://github.com/tardyp/sphinx-jinja'
+license=(MIT)
+depends=(python python-docutils python-jinja python-sphinx)
+makedepends=(python-setuptools python-pbr)
+checkdepends=(python-nose python-sphinx-testing)
+source=("https://files.pythonhosted.org/packages/source/s/sphinx-jinja/sphinx-jinja-$pkgver.tar.gz")
+sha256sums=('372406fe557be7c3f000ddd0ff130e7bb2d83f47df02e255fd24fe62d81ee143')
+
+build() {
+ cd sphinx-jinja-$pkgver
+ python setup.py build
+}
+
+check() {
+ cd sphinx-jinja-$pkgver
+ # Running tests with 'nosetests' fails with issues around namespace packages
+ python -m nose -v
+}
+
+package() {
+ cd sphinx-jinja-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+ install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}
More information about the arch-commits
mailing list