[arch-commits] Commit in haskell-yesod-core/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Feb 2 16:53:47 UTC 2020


    Date: Sunday, February 2, 2020 @ 16:53:45
  Author: felixonmars
Revision: 561719

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-core/repos/community-staging-x86_64/
  haskell-yesod-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 561718, haskell-yesod-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-yesod-core/repos/community-staging-x86_64/PKGBUILD (from rev 561718, haskell-yesod-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-02 16:53:45 UTC (rev 561719)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod-core
+pkgname=haskell-yesod-core
+pkgver=1.6.17.1
+pkgrel=10
+pkgdesc="Creation of type-safe, RESTful web applications."
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-auto-update' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-case-insensitive' 'haskell-cereal'
+         'haskell-clientsession' 'haskell-conduit' 'haskell-conduit-extra' 'haskell-cookie'
+         'haskell-fast-logger' 'haskell-http-types' 'haskell-memory'
+         'haskell-monad-logger' 'haskell-old-locale' 'haskell-path-pieces' 'haskell-primitive'
+         'haskell-random' 'haskell-resourcet' 'haskell-shakespeare' 'haskell-unix-compat'
+         'haskell-unliftio' 'haskell-unordered-containers' 'haskell-vector' 'haskell-wai'
+         'haskell-wai-extra' 'haskell-wai-logger' 'haskell-warp' 'haskell-word8')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('f7c2989a427d4606a6682ecad3739b512c4a74e45447e087f190d50642a1b4fd4ab0cb9d89664b7b8fd31ba85eaf62cad899151497af9d906441c81a922f1935')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list