[arch-commits] Commit in minikube/repos (2 files)

[Lukas Fleischer]

    Date: Thursday, February 6, 2020 @ 11:02:05
  Author: lfleischer
Revision: 563613

archrelease: copy trunk to community-testing-x86_64

Added:
  minikube/repos/community-testing-x86_64/
  minikube/repos/community-testing-x86_64/PKGBUILD
    (from rev 563612, minikube/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: minikube/repos/community-testing-x86_64/PKGBUILD (from rev 563612, minikube/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-02-06 11:02:05 UTC (rev 563613)
@@ -0,0 +1,38 @@
+# Maintainer: Christian Rebischke <chris.rebischke at archlinux.org>
+# Contributor: Ivan Shapovalov <intelfx at intelfx.name>
+
+pkgname=minikube
+pkgver=1.7.1
+_minikube_commit=54f28ac5d3a815d1196cd5d57d707439ee4bb392
+pkgrel=1
+pkgdesc="Minikube is a tool that makes it easy to run Kubernetes locally"
+url="https://github.com/kubernetes/minikube"
+license=('Apache')
+arch=('x86_64')
+optdepends=(
+  'kubectl: to manage the cluster'
+  'virtualbox: to use --vm-driver=virtualbox'
+)
+makedepends=('git' 'go-pie' 'go-bindata')
+depends=('glibc')
+source=("git+https://github.com/kubernetes/minikube.git#commit=${_minikube_commit}")
+md5sums=('SKIP')
+
+prepare() {
+  rm -rf "$srcdir/src"
+  mkdir -p "$srcdir/src/k8s.io"
+  mv -T "$srcdir/minikube" "$srcdir/src/k8s.io/minikube"
+}
+
+build() {
+  export GOPATH="$srcdir"
+  cd "$GOPATH/src/k8s.io/minikube"
+  make
+}
+
+package() {
+  install -Dm755 "$srcdir/src/k8s.io/minikube/out/minikube" -t "$pkgdir/usr/bin"
+
+  "$pkgdir/usr/bin/minikube" completion bash | install -Dm644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/minikube"
+  "$pkgdir/usr/bin/minikube" completion zsh | install -Dm644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_minikube"
+}