[arch-commits] Commit in stylish-haskell/repos (2 files)

[Felix Yan]

    Date: Saturday, February 8, 2020 @ 13:34:50
  Author: felixonmars
Revision: 564102

archrelease: copy trunk to community-staging-x86_64

Added:
  stylish-haskell/repos/community-staging-x86_64/
  stylish-haskell/repos/community-staging-x86_64/PKGBUILD
    (from rev 564101, stylish-haskell/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: stylish-haskell/repos/community-staging-x86_64/PKGBUILD (from rev 564101, stylish-haskell/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-02-08 13:34:50 UTC (rev 564102)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=stylish-haskell
+pkgver=0.9.4.4
+pkgrel=28
+pkgdesc="Haskell code prettifier"
+url="https://github.com/jaspervdj/stylish-haskell"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-file-embed' 'haskell-optparse-applicative'
+         'haskell-src-exts' 'haskell-strict' 'haskell-syb' 'haskell-yaml')
+makedepends=('ghc' 'haskell-hunit' 'haskell-random' 'haskell-test-framework'
+             'haskell-test-framework-hunit')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('5226d203295e03600f07fe21905a1ea1231bd79b1d7bc5e157c74f79054181df0e5f7d549dd418de0a610d70450ba1f2ae9d9ff804fa21674dacd0c17fb26bc9')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -i -e '/semigroups/d' $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-old_base --ghc-option='-pie'
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}